{
  description = "CLI to read/write state associated with the newsflash library/program";
  inputs = {
    nixpkgs.url = "nixpkgs/nixos-22.05";
    flake-utils.url = github:numtide/flake-utils;
    rust-overlay.url = github:oxalica/rust-overlay;
  };

  outputs = { self, nixpkgs, flake-utils, rust-overlay }:
    with flake-utils.lib; eachSystem allSystems (system:
    let
      pkgs = import nixpkgs {
        inherit system;
        overlays = [ rust-overlay.overlays.default ];
      };
      rust-toolchain = pkgs.rust-bin.stable.latest.default;
      buildInputs = with pkgs; [ openssl libxml2 ];
      nativeBuildInputs = with pkgs; [ pkg-config rust-toolchain ];
    in
    rec {
      packages = {
        # docs: <nixpkgs>/doc/languages-frameworks/rust.section.md
        # docs: https://github.com/oxalica/rust-overlay
        news-flash-cli = pkgs.rustPlatform.buildRustPackage {
          name = "news-flash-cli";
          inherit buildInputs nativeBuildInputs;
          src = ./.;
          cargoLock = {
            lockFile = ./Cargo.lock;
            outputHashes = {
             "news-flash-2.0.0-alpha.0" = "sha256-eRhyLnogOv44BpmPJUfeV2KVoUKsigYUfzIN3lKpDnc=";
            };
          };
          # enables debug builds, if we want: https://github.com/NixOS/nixpkgs/issues/60919.
          hardeningDisable = [ "fortify" ];
        };
      };
      defaultPackage = packages.news-flash-cli;

      devShells.default = with pkgs; mkShell {
        # enables debug builds, if we want: https://github.com/NixOS/nixpkgs/issues/60919.
        hardeningDisable = [ "fortify" ];

        # Allow cargo to download crates.
        SSL_CERT_FILE = "${cacert}/etc/ssl/certs/ca-bundle.crt";

        # include both build and runtime deps in the shell so once can build and run the result.
        buildInputs = buildInputs ++ nativeBuildInputs;
      };
    });
}