pipeline: init at 1.14.1

note that this doesn't cross compile, because of stupid fucking rust build.rs scripts

thanks, openssl-sys

pkgs/additional/pipeline/default.nix

@@ -0,0 +1,61 @@
+{ lib
+, stdenv
+, cargo
+, desktop-file-utils
+, fetchFromGitLab
+, libadwaita
+, meson
+, ninja
+, openssl
+, pkg-config
+, rustPlatform
+, rustc
+, wrapGAppsHook4
+}:
+
+stdenv.mkDerivation rec {
+  pname = "pipeline";
+  version = "1.14.1";
+
+  src = fetchFromGitLab {
+    domain = "gitlab.com";
+    owner = "schmiddi-on-mobile";
+    repo = "pipeline";
+    rev = "v${version}";
+    hash = "sha256-CQFxNA6gC5mUdyFbf/oMK5kLtzRhglXCDHnyb9XQOSg=";
+  };
+
+  cargoDeps = rustPlatform.importCargoLock {
+    lockFile = ./Cargo.lock;
+    outputHashes = {
+      "tf_core-0.1.4" = "sha256-bWkF1ezdDZyuP2zo5EIvB/Br6HFpdmkDijpQii/4i68=";
+    };
+  };
+
+  nativeBuildInputs = [
+    cargo
+    desktop-file-utils
+    meson
+    ninja
+    pkg-config
+    rustPlatform.cargoSetupHook
+    rustc
+    wrapGAppsHook4
+  ];
+
+  buildInputs = [
+    libadwaita
+    openssl
+  ];
+
+  meta = {
+    changelog = "https://gitlab.com/schmiddi-on-mobile/pipeline/-/blob/${src.rev}/CHANGELOG.md";
+    description = "Watch YouTube and PeerTube videos in one place";
+    homepage = "https://gitlab.com/schmiddi-on-mobile/pipeline";
+    license = lib.licenses.gpl3Plus;
+    maintainers = with lib.maintainers; [ colinsane ];
+    platforms = lib.platforms.linux;
+    mainProgram = "tubefeeder";
+  };
+}
+

pkgs/default.nix

@@ -51,6 +51,7 @@ let
     mpv-uosc-latest = callPackage ./additional/mpv-uosc-latest { };
     mx-sanebot = callPackage ./additional/mx-sanebot { };
     phog = callPackage ./additional/phog { };
+    pipeline = callPackage ./additional/pipeline { };
     rtl8723cs-firmware = callPackage ./additional/rtl8723cs-firmware { };
     rtl8723cs-wowlan = callPackage ./additional/rtl8723cs-wowlan { };
     sane-scripts = lib.recurseIntoAttrs (callPackage ./additional/sane-scripts { });