qmk-firmware: init at 0.25.9

pkgs/additional/qmk-packages/default.nix

@@ -0,0 +1,13 @@
+{
+  lib,
+  newScope,
+}:
+lib.makeScope newScope (self: with self; {
+  mkQmkFirmware = { keyboard ? "all", keymap ? "all" }:
+    callPackage ./firmware.nix {
+      inherit keyboard keymap;
+    };
+
+  all = mkQmkFirmware { };
+  ergodox_ez = mkQmkFirmware { keyboard = "ergodox_ez"; };
+})

pkgs/additional/qmk-packages/firmware.nix

@@ -0,0 +1,34 @@
+{
+  fetchFromGitHub,
+  nix-update-script,
+  qmk,
+  stdenv,
+  keyboard ? "all",
+  keymap ? "all",
+}:
+stdenv.mkDerivation (finalAttrs: {
+  pname = "qmk-firmware-${keyboard}-${keymap}";
+  version = "0.25.9";
+
+  src = fetchFromGitHub {
+    owner = "qmk";
+    repo = "qmk_firmware";
+    rev = finalAttrs.version;
+    hash = "sha256-M0kLGbte1wq5teD56IFd8uWCIvpra8dz2b0bjxlTzx0=";
+    fetchSubmodules = true;
+  };
+
+  nativeBuildInputs = [
+    qmk
+  ];
+
+  makeFlags = [ "${keyboard}:${keymap}" ];
+
+  # seems to still use just one core, so don't try to build all keyboards unless you hate yourself.
+  enableParallelBuilding = true;
+
+  installPhase = ''
+    mkdir -p $out/share/qmk
+    install -Dm644 *.hex $out/share/qmk
+  '';
+})

pkgs/default.nix

@@ -80,6 +80,7 @@ let
     pyln-bolt7 = callPackage ./additional/pyln-bolt7 { };
     pyln-client = callPackage ./additional/pyln-client { };
     pyln-proto = callPackage ./additional/pyln-proto { };
+    qmkPackages = recurseIntoAttrs (callPackage ./additional/qmk-packages { });
     rtl8723cs-firmware = callPackage ./additional/rtl8723cs-firmware { };
     rtl8723cs-wowlan = callPackage ./additional/rtl8723cs-wowlan { };
     sane-backgrounds = callPackage ./additional/sane-backgrounds { };