pinentry_qt5: init at 0.9.6

pkgs/tools/security/pinentry/qt5.nix

@@ -0,0 +1,47 @@
+{ fetchurl, stdenv, pkgconfig
+, libgpgerror, libassuan
+, qtbase
+, libcap ? null
+}:
+
+let
+  mkFlag = pfxTrue: pfxFalse: cond: name: "--${if cond then pfxTrue else pfxFalse}-${name}";
+  mkEnable = mkFlag "enable" "disable";
+  mkWith = mkFlag "with" "without";
+in
+with stdenv.lib;
+stdenv.mkDerivation rec {
+  name = "pinentry-0.9.6";
+
+  src = fetchurl {
+    url = "mirror://gnupg/pinentry/${name}.tar.bz2";
+    sha256 = "0rhyw1vk28kgasjp22myf7m2q8kycw82d65pr9kgh93z17lj849a";
+  };
+
+  buildInputs = [ libgpgerror libassuan libcap qtbase ];
+
+  # configure cannot find moc on its own
+  preConfigure = ''
+    export QTDIR="${qtbase}"
+    export MOC="${qtbase}/bin/moc"
+  '';
+
+  configureFlags = [
+    (mkWith   (libcap != null)  "libcap")
+    (mkEnable true "pinentry-qt")
+  ];
+
+  nativeBuildInputs = [ pkgconfig ];
+
+  meta = {
+    homepage = "http://gnupg.org/aegypten2/";
+    description = "GnuPG's interface to passphrase input";
+    license = stdenv.lib.licenses.gpl2Plus;
+    platforms = stdenv.lib.platforms.all;
+    longDescription = ''
+      Pinentry provides a console and (optional) GTK+ and Qt GUIs allowing users
+      to enter a passphrase when `gpg' or `gpg2' is run and needs it.
+    '';
+    maintainers = [ stdenv.lib.maintainers.ttuegel ];
+  };
+}

pkgs/top-level/all-packages.nix

@@ -2711,6 +2711,10 @@ let
     qt4 = null;
   };
 
+  pinentry_qt5 = qt55Libs.callPackage ../tools/security/pinentry/qt5.nix {
+    libcap = if stdenv.isDarwin then null else libcap;
+  };
+
   pius = callPackage ../tools/security/pius { };
 
   pk2cmd = callPackage ../tools/misc/pk2cmd { };