diff --git a/pkgs/tools/system/hardinfo/default.nix b/pkgs/tools/system/hardinfo/default.nix
new file mode 100644
index 000000000000..11236b7a9d10
--- /dev/null
+++ b/pkgs/tools/system/hardinfo/default.nix
@@ -0,0 +1,45 @@
+{ stdenv, fetchurl, which, pkgconfig, gtk2, pcre, glib, libxml2
+, libsoup ? null
+}:
+
+stdenv.mkDerivation rec {
+  name = "hardinfo-${version}";
+  version = "0.5.1";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/project/hardinfo.berlios/hardinfo-${version}.tar.bz2";
+    sha256 = "0yhvfc5icam3i4mphlz0m9d9d2irjw8mbsxq203x59wjgh6nrpx0";
+  };
+
+  # Not adding 'hostname' command, the build shouldn't depend on what the build
+  # host is called.
+  buildInputs = [ which pkgconfig gtk2 pcre glib libxml2 libsoup ];
+
+  # Fixes '#error You must compile this program without "-O"'
+  hardeningDisable = [ "all" ];
+
+  preConfigure = ''
+    patchShebangs configure
+
+    # -std=gnu89 fixes build error, copied from
+    # https://bugs.debian.org/cgi-bin/bugreport.cgi?bug=757525
+    sed -i -e "s/^CFLAGS = \(.*\)/CFLAGS = \1 -std=gnu89/" Makefile.in
+
+    substituteInPlace ./arch/linux/common/modules.h --replace /sbin/modinfo modinfo
+  '';
+
+  # Makefile supports DESTDIR but not PREFIX (it hardcodes $DESTDIR/usr/).
+  installFlags = [ "DESTDIR=$(out)" ];
+  postInstall = ''
+    mv "$out/usr/"* "$out"
+    rmdir "$out/usr"
+  '';
+
+  meta = with stdenv.lib; {
+    homepage = http://hardinfo.org/;
+    description = "Display information about your hardware and operating system";
+    license = licenses.gpl2;
+    maintainers = with maintainers; [ bjornfor ];
+    platforms = platforms.linux;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 90e44c9819ac..a2c08d2eea87 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -2150,6 +2150,8 @@ with pkgs;
 
   halibut = callPackage ../tools/typesetting/halibut { };
 
+  hardinfo = callPackage ../tools/system/hardinfo { };
+
   hdapsd = callPackage ../os-specific/linux/hdapsd { };
 
   hddtemp = callPackage ../tools/misc/hddtemp { };