From 446a718d13088aea9e15503f04e56d5f868ed91c Mon Sep 17 00:00:00 2001
From: Martin Weinelt <hexa@darmstadt.ccc.de>
Date: Sat, 10 Sep 2022 01:58:49 +0200
Subject: [PATCH] meerk40t: init at 0.8.0031

MeerK40t LaserCutter Software
https://github.com/meerk40t/meerk40t
---
 pkgs/applications/misc/meerk40t/default.nix | 95 +++++++++++++++++++++
 pkgs/top-level/all-packages.nix             |  2 +
 2 files changed, 97 insertions(+)
 create mode 100644 pkgs/applications/misc/meerk40t/default.nix

diff --git a/pkgs/applications/misc/meerk40t/default.nix b/pkgs/applications/misc/meerk40t/default.nix
new file mode 100644
index 000000000000..28a136c9a257
--- /dev/null
+++ b/pkgs/applications/misc/meerk40t/default.nix
@@ -0,0 +1,95 @@
+{ lib
+, fetchFromGitHub
+, python3
+, gtk3
+, wrapGAppsHook
+}:
+
+let
+  inherit (python3.pkgs) buildPythonApplication buildPythonPackage fetchPypi;
+
+  meerk40t-camera = buildPythonPackage rec {
+    pname = "meerk40t-camera";
+    version = "0.1.9";
+    format = "setuptools";
+
+    src = fetchPypi {
+      inherit pname version;
+      hash = "sha256-uGCBHdgWoorVX2XqMCg0YBweb00sQ9ZSbJe8rlGeovs=";
+    };
+
+    postPatch = ''
+      sed -i '/meerk40t/d' setup.py
+    '';
+
+    propagatedBuildInputs = with python3.pkgs; [
+      opencv4
+    ];
+
+    pythonImportsCheck = [
+      "camera"
+    ];
+
+    doCheck = false;
+
+    meta = with lib; {
+      description = "MeerK40t camera plugin";
+      license = licenses.mit;
+      homepage = "https://github.com/meerk40t/meerk40t-camera";
+      maintainers = with maintainers; [ hexa ];
+    };
+  };
+in
+buildPythonApplication rec {
+  pname = "MeerK40t";
+  version = "0.8.0031";
+  format = "setuptools";
+
+  src = fetchFromGitHub {
+    owner = "meerk40t";
+    repo = pname;
+    rev = "refs/tags/${version}";
+    hash = "sha256-7Vc7Z+mxy+xRbUBeivkqVwO86ovZDo42M4G0ZD23vMk=";
+  };
+
+  nativeBuildInputs = [
+    wrapGAppsHook
+  ];
+
+  # prevent double wrapping
+  dontWrapGApps = true;
+
+  propagatedBuildInputs = with python3.pkgs; [
+    ezdxf
+    meerk40t-camera
+    opencv4
+    pillow
+    pyserial
+    pyusb
+    setuptools
+    wxPython_4_2
+  ];
+
+  preFixup = ''
+    gappsWrapperArgs+=(
+      --prefix XDG_DATA_DIRS : "${gtk3}/share/gsettings-schemas/${gtk3.name}"
+    )
+    makeWrapperArgs+=("''${gappsWrapperArgs[@]}")
+  '';
+
+  checkInputs = with python3.pkgs; [
+    unittestCheckHook
+  ];
+
+  preCheck = ''
+    export HOME=$TMPDIR
+  '';
+
+  meta = with lib; {
+    changelog = "https://github.com/meerk40t/meerk40t/releases/tag/${version}";
+    description = "MeerK40t LaserCutter Software";
+    homepage = "https://github.com/meerk40t/meerk40t";
+    license = licenses.mit;
+    maintainers = with maintainers; [ hexa ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 931151f94568..0f30d6fd0601 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -28701,6 +28701,8 @@ with pkgs;
 
   marker = callPackage ../applications/editors/marker { };
 
+  meerk40t = callPackage ../applications/misc/meerk40t { };
+
   musikcube = callPackage ../applications/audio/musikcube {
     inherit (darwin.apple_sdk.frameworks) Cocoa SystemConfiguration;
   };