mozphab: 0.1.99 -> 1.1.0; rename from moz-phab

and enable the tests.

pkgs/applications/misc/moz-phab/default.nix

@@ -1,59 +0,0 @@
-{ lib
-, buildPythonApplication
-, fetchPypi
-, mercurial
-# build inputs
-, distro
-, glean-sdk
-, pip
-, python-hglib
-, sentry-sdk
-, setuptools
-}:
-
-buildPythonApplication rec {
-  pname = "moz-phab";
-  version = "0.1.99";
-
-  src = fetchPypi {
-    pname = "MozPhab";
-    inherit version;
-    sha256 = "sha256-uKoMMSp5AIvB1qTRYAh7n1+2dDLneFbssfkfTTshfcs=";
-  };
-
-  # Relax python-hglib requirement
-  # https://phabricator.services.mozilla.com/D131618
-  postPatch = ''
-    substituteInPlace setup.py \
-      --replace "==" ">="
-  '';
-
-  propagatedBuildInputs = [
-    distro
-    glean-sdk
-    pip
-    python-hglib
-    sentry-sdk
-    setuptools
-  ];
-  checkInputs = [
-    mercurial
-  ];
-
-  preCheck = ''
-    export HOME=$(mktemp -d)
-  '';
-
-  meta = with lib; {
-    description = "Phabricator CLI from Mozilla to support submission of a series of commits";
-    longDescription = ''
-      moz-phab is a custom command-line tool, which communicates to
-      Phabricator’s API, providing several conveniences, including support for
-      submitting series of commits.
-    '';
-    homepage = "https://moz-conduit.readthedocs.io/en/latest/phabricator-user.html";
-    license = licenses.mpl20;
-    maintainers = [];
-    platforms = platforms.unix;
-  };
-}

pkgs/applications/misc/mozphab/default.nix

@@ -0,0 +1,78 @@
+{ lib
+, fetchFromGitHub
+, python3
+
+# tests
+, git
+, mercurial
+, patch
+}:
+
+python3.pkgs.buildPythonApplication rec {
+  pname = "mozphab";
+  version = "1.1.0";
+  format = "setuptools";
+
+  src = fetchFromGitHub {
+    owner = "mozilla-conduit";
+    repo = "review";
+    rev = "refs/tags/${version}";
+    hash = "sha256-vLHikGjTYOeXd6jDRsoCkq3i0eh6Ttd4KdvlixjzdZ4=";
+  };
+
+  postPatch = ''
+    substituteInPlace setup.py \
+      --replace "glean-sdk>=50.0.1,==50.*" "glean-sdk"
+  '';
+
+  propagatedBuildInputs = with python3.pkgs; [
+    distro
+    glean-sdk
+    packaging
+    python-hglib
+    sentry-sdk
+    setuptools
+  ];
+
+  checkInputs = [
+    git
+    mercurial
+    patch
+  ]
+  ++ (with python3.pkgs; [
+    callee
+    immutabledict
+    hg-evolve
+    mock
+    pytestCheckHook
+  ]);
+
+  preCheck = ''
+    export HOME=$(mktemp -d)
+  '';
+
+  disabledTestPaths = [
+    # codestyle doesn't matter to us
+    "tests/test_style.py"
+    # integration tests try to submit changes, which requires network access
+    "tests/test_integration_git.py"
+    "tests/test_integration_hg.py"
+    "tests/test_integration_hg_dag.py"
+    "tests/test_integration_patch.py"
+    "tests/test_integration_reorganise.py"
+    "tests/test_sentry.py"
+  ];
+
+  meta = with lib; {
+    description = "Phabricator CLI from Mozilla to support submission of a series of commits";
+    longDescription = ''
+      moz-phab is a custom command-line tool, which communicates to
+      Phabricator’s API, providing several conveniences, including support for
+      submitting series of commits.
+    '';
+    homepage = "https://moz-conduit.readthedocs.io/en/latest/phabricator-user.html";
+    license = licenses.mpl20;
+    maintainers = with maintainers; [];
+    platforms = platforms.unix;
+  };
+}

pkgs/top-level/aliases.nix

@@ -895,6 +895,7 @@ mapAliases ({
   mopidy-spotify-tunigo = throw "mopidy-spotify-tunigo has been removed because Spotify stopped supporting libspotify"; # added 2022-05-29
 
   morituri = throw "'morituri' has been renamed to/replaced by 'whipper'"; # Converted to throw 2022-02-22
+  moz-phab = mozphab; # Added 2022-08-09
   mozart-binary = mozart2-binary; # Added 2019-09-23
   mozart = mozart2-binary; # Added 2019-09-23
   mpc_cli = mpc-cli; # moved from top-level 2022-01-24

pkgs/top-level/all-packages.nix

@@ -8128,7 +8128,7 @@ with pkgs;
 
   motion = callPackage ../applications/video/motion { };
 
-  moz-phab = python3Packages.callPackage ../applications/misc/moz-phab { };
+  mozphab = callPackage ../applications/misc/mozphab { };
 
   mtail = callPackage ../servers/monitoring/mtail { };