diff --git a/maintainers/maintainer-list.nix b/maintainers/maintainer-list.nix
index 37dfd12c2df6..498f0f183f75 100644
--- a/maintainers/maintainer-list.nix
+++ b/maintainers/maintainer-list.nix
@@ -15825,6 +15825,12 @@
     githubId = 1179566;
     name = "Nicolas B. Pierron";
   };
+  pigeonf = {
+    email = "fnoegip+nixpkgs@gmail.com";
+    github = "PigeonF";
+    githubId = 7536431;
+    name = "Jonas Fierlings";
+  };
   pimeys = {
     email = "julius@nauk.io";
     github = "pimeys";
diff --git a/pkgs/by-name/co/committed/package.nix b/pkgs/by-name/co/committed/package.nix
new file mode 100644
index 000000000000..cd42172fde9f
--- /dev/null
+++ b/pkgs/by-name/co/committed/package.nix
@@ -0,0 +1,43 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+, rustPlatform
+, darwin
+, testers
+, nix-update-script
+, committed
+}:
+let
+  version = "1.0.20";
+in
+rustPlatform.buildRustPackage {
+  pname = "committed";
+  inherit version;
+
+  src = fetchFromGitHub {
+    owner = "crate-ci";
+    repo = "committed";
+    rev = "refs/tags/v${version}";
+    hash = "sha256-HqZYxV2YjnK7Q3A7B6yVFXME0oc3DZ4RfMkDGa2IQxA=";
+  };
+  cargoHash = "sha256-AmAEGVWq6KxLtiHDGIFVcoP1Wck8z+P9mnDy0SSSJNM=";
+
+  buildInputs = lib.optionals stdenv.isDarwin [ darwin.apple_sdk.frameworks.Security ];
+
+  passthru = {
+    tests.version = testers.testVersion { package = committed; };
+    updateScript = nix-update-script { };
+  };
+
+  meta = {
+    homepage = "https://github.com/crate-ci/committed";
+    changelog = "https://github.com/crate-ci/committed/blob/v${version}/CHANGELOG.md";
+    description = "Nitpicking commit history since beabf39";
+    mainProgram = "committed";
+    license = [
+      lib.licenses.asl20 # or
+      lib.licenses.mit
+    ];
+    maintainers = [ lib.maintainers.pigeonf ];
+  };
+}