Merge pull request #259238 from OPNA2608/init/lomiri/lomiri-settings-components

lomiri.lomiri-settings-components: init at 1.1.0

pkgs/desktops/lomiri/default.nix

@@ -19,6 +19,9 @@ let
     lomiri-api = callPackage ./development/lomiri-api { };
     u1db-qt = callPackage ./development/u1db-qt { };
 
+    #### QML / QML-related
+    lomiri-settings-components = callPackage ./qml/lomiri-settings-components { };
+
     #### Services
     biometryd = callPackage ./services/biometryd { };
     hfd-service = callPackage ./services/hfd-service { };

pkgs/desktops/lomiri/qml/lomiri-settings-components/default.nix

@@ -0,0 +1,65 @@
+{ stdenv
+, lib
+, fetchFromGitLab
+, gitUpdater
+, cmake
+, cmake-extras
+, pkg-config
+, python3
+, qtbase
+, qtdeclarative
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "lomiri-settings-components";
+  version = "1.1.0";
+
+  src = fetchFromGitLab {
+    owner = "ubports";
+    repo = "development/core/lomiri-settings-components";
+    rev = finalAttrs.version;
+    hash = "sha256-13uxUBM+uOmt8X0uLGWNP8YbwCdb2QCChB8IP3td5a4=";
+  };
+
+  postPatch = ''
+    patchShebangs tests/imports/check_imports.py
+
+    substituteInPlace CMakeLists.txt \
+      --replace "\''${CMAKE_INSTALL_LIBDIR}/qt5/qml" '${placeholder "out"}/${qtbase.qtQmlPrefix}'
+  '' + lib.optionalString (!finalAttrs.doCheck) ''
+    sed -i CMakeLists.txt \
+      -e '/add_subdirectory(tests)/d'
+  '';
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+  ];
+
+  buildInputs = [
+    cmake-extras
+    qtbase
+    qtdeclarative
+  ];
+
+  nativeCheckInputs = [
+    python3
+  ];
+
+  # No apps, just QML components
+  dontWrapQtApps = true;
+
+  doCheck = stdenv.buildPlatform.canExecute stdenv.hostPlatform;
+
+  passthru.updateScript = gitUpdater { };
+
+  meta = with lib; {
+    description = "QML settings components for the Lomiri Desktop Environment";
+    homepage = "https://gitlab.com/ubports/development/core/lomiri-settings-components";
+    license = licenses.lgpl3Only;
+    maintainers = teams.lomiri.members;
+    platforms = platforms.linux;
+  };
+})