Merge pull request #277735: Remove caadar from maintainers

maintainers/maintainer-list.nix

@@ -2867,12 +2867,6 @@
     githubId = 382011;
     name = "c4605";
   };
-  caadar = {
-    email = "v88m@posteo.net";
-    github = "caadar";
-    githubId = 15320726;
-    name = "Car Cdr";
-  };
   caarlos0 = {
     name = "Carlos A Becker";
     email = "carlos@becker.software";

pkgs/by-name/di/disk-filltest/package.nix

@@ -0,0 +1,43 @@
+{ lib
+, stdenv
+, fetchFromGitHub
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "disk-filltest";
+  version = "0.8.2";
+
+  src = fetchFromGitHub {
+    owner = "bingmann";
+    repo = "disk-filltest";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-cppofTzzJHrvG5SsafKgvCIiHc6E5740NyQdWWZxrGI=";
+  };
+
+  outputs = [ "out" "doc" "man" ];
+
+  makeFlags = [
+    "CC=${stdenv.cc.targetPrefix}cc"
+    "prefix=${placeholder "out"}"
+    "man1dir=${placeholder "man"}/share/man/man1"
+  ];
+
+  postInstall = ''
+    install -D -m0644 -t $doc/share/doc/disk-filltest README
+  '';
+
+  meta = {
+    homepage = "https://panthema.net/2013/disk-filltest";
+    description = "Simple program to detect bad disks by filling them with random data";
+    longDescription = ''
+      disk-filltest is a tool to check storage disks for coming failures by
+      write files with pseudo-random data to the current directory until the
+      disk is full, read the files again and verify the sequence written. It
+      also can measure read/write speed while filling the disk.
+    '';
+    license = lib.licenses.gpl3Plus;
+    mainProgram = "disk-filltest";
+    maintainers = with lib.maintainers; [ AndersonTorres ];
+    platforms = lib.platforms.all;
+  };
+})

pkgs/by-name/gt/gtklp/package.nix

@@ -0,0 +1,71 @@
+{ lib
+, stdenv
+, autoreconfHook
+, cups
+, fetchurl
+, gettext
+, glib
+, gtk2
+, libtool
+, openssl
+, pkg-config
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "gtklp";
+  version = "1.3.4";
+
+  src = fetchurl {
+    url = "mirror://sourceforge/gtklp/gtklp-${finalAttrs.version}.src.tar.gz";
+    hash = "sha256-vgdgkEJZX6kyA047LXA4zvM5AewIY/ztu1GIrLa1O6s=";
+  };
+
+  nativeBuildInputs = [
+    autoreconfHook
+    pkg-config
+    cups
+  ];
+
+  buildInputs = [
+    cups
+    gettext
+    glib
+    gtk2
+    libtool
+    openssl
+  ];
+
+  outputs = [ "out" "doc" "man" ];
+
+  strictDeps = true;
+
+  patches = [
+    ./000-autoconf.patch
+    ./001-format-parameter.patch
+  ];
+
+  # Workaround build failure on -fno-common toolchains:
+  #   ld: libgtklp.a(libgtklp.o):libgtklp/libgtklp.h:83: multiple definition of `progressBar';
+  #     file.o:libgtklp/libgtklp.h:83: first defined here
+  env.NIX_CFLAGS_COMPILE = "-fcommon";
+
+  postPatch = ''
+    substituteInPlace include/defaults.h \
+      --replace "netscape" "firefox" \
+      --replace "http://localhost:631/sum.html#STANDARD_OPTIONS" \
+                "http://localhost:631/help/"
+  '';
+
+  preInstall = ''
+    install -D -m0644 -t $doc/share/doc AUTHORS BUGS ChangeLog README USAGE
+  '';
+
+  meta = {
+    homepage = "https://gtklp.sirtobi.com";
+    description = "A GTK-based graphical frontend for CUPS";
+    license = with lib.licenses; [ gpl2Only ];
+    mainProgram = "gtklp";
+    maintainers = with lib.maintainers; [ AndersonTorres ];
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/by-name/ss/ssh-askpass-fullscreen/package.nix

@@ -0,0 +1,42 @@
+{ lib
+, stdenv
+, autoreconfHook
+, fetchFromGitHub
+, gtk2
+, openssh
+, pkg-config
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "ssh-askpass-fullscreen";
+  version = "1.3";
+
+  src = fetchFromGitHub {
+    owner = "atj";
+    repo = "ssh-askpass-fullscreen";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-1GER+SxTpbMiYLwFCwLX/hLvzCIqutyvQc9DNJ7d1C0=";
+  };
+
+  nativeBuildInputs = [
+    autoreconfHook
+    pkg-config
+  ];
+
+  buildInputs = [
+    gtk2
+    openssh
+  ];
+
+  strictDeps = true;
+
+  meta = {
+    homepage = "https://github.com/atj/ssh-askpass-fullscreen";
+    broken = stdenv.isDarwin;
+    description = "A small, fullscreen SSH askpass GUI using GTK+2";
+    license = with lib.licenses; [ gpl2Plus ];
+    mainProgram = "ssh-askpass-fullscreen";
+    maintainers = with lib.maintainers; [ AndersonTorres ];
+    platforms = lib.platforms.unix;
+  };
+})

pkgs/tools/misc/gtklp/default.nix

@@ -1,57 +0,0 @@
-{ stdenv, lib, fetchurl
-, autoreconfHook, libtool, pkg-config
-, gtk2, glib, cups, gettext, openssl
-}:
-
-stdenv.mkDerivation rec {
-  pname = "gtklp";
-  version = "1.3.4";
-
-  src = fetchurl {
-    url = "mirror://sourceforge/${pname}/${pname}-${version}.src.tar.gz";
-    sha256 = "1arvnnvar22ipgnzqqq8xh0kkwyf71q2sfsf0crajpsr8a8601xy";
-  };
-
-  nativeBuildInputs = [
-    pkg-config
-    autoreconfHook
-  ];
-
-  buildInputs = [
-    cups
-    gettext
-    glib
-    gtk2
-    libtool
-    openssl
-  ];
-
-  patches = [
-    ./patches/mdv-fix-str-fmt.patch
-    ./patches/autoconf.patch
-  ];
-
-  # Workaround build failure on -fno-common toolchains:
-  #   ld: libgtklp.a(libgtklp.o):libgtklp/libgtklp.h:83: multiple definition of `progressBar';
-  #     file.o:libgtklp/libgtklp.h:83: first defined here
-  env.NIX_CFLAGS_COMPILE = "-fcommon";
-
-  preConfigure = ''
-    substituteInPlace include/defaults.h --replace "netscape" "firefox"
-    substituteInPlace include/defaults.h --replace "http://localhost:631/sum.html#STANDARD_OPTIONS" \
-                                                   "http://localhost:631/help/"
-  '';
-
-  preInstall = ''
-    install -D -m0644 -t $out/share/doc AUTHORS BUGS ChangeLog README USAGE
-  '';
-
-  meta = with lib; {
-    description = "A graphical frontend for CUPS";
-    homepage = "https://gtklp.sirtobi.com";
-    license = licenses.gpl2Only;
-    maintainers = with maintainers; [ caadar ];
-    platforms = platforms.unix;
-  };
-
-}

pkgs/tools/networking/ssh-askpass-fullscreen/default.nix

@@ -1,32 +0,0 @@
-{ lib, stdenv, fetchFromGitHub, autoreconfHook, pkg-config, gtk2, openssh }:
-
-stdenv.mkDerivation rec {
-  pname = "ssh-askpass-fullscreen";
-  version = "1.3";
-
-  src = fetchFromGitHub {
-    owner = "atj";
-    repo = pname;
-    rev = "v${version}";
-    sha256 = "sha256-1GER+SxTpbMiYLwFCwLX/hLvzCIqutyvQc9DNJ7d1C0=";
-  };
-
-  nativeBuildInputs = [
-    autoreconfHook
-    pkg-config
-  ];
-
-  buildInputs = [
-    gtk2
-    openssh
-  ];
-
-  meta = with lib; {
-    broken = stdenv.isDarwin;
-    description = "A small SSH askpass GUI using GTK+2";
-    homepage = "https://github.com/atj/ssh-askpass-fullscreen";
-    license = licenses.gpl2;
-    maintainers = with maintainers; [ caadar ];
-    platforms = platforms.unix;
-  };
-}

pkgs/tools/system/disk-filltest/default.nix

@@ -1,39 +0,0 @@
-{ lib, stdenv, fetchFromGitHub }:
-
-stdenv.mkDerivation rec {
-  pname = "disk-filltest";
-  version = "0.8.2";
-
-  src = fetchFromGitHub {
-    owner = "bingmann";
-    repo = "disk-filltest";
-    rev = "v${version}";
-    sha256 = "0qmcf5k5j7946wsbxrw4rqfj48mwl3r6kb4l3gppl97k7iyni6kj";
-  };
-
-  preBuild = ''
-    substituteInPlace Makefile --replace 'prefix = /usr/local' 'prefix = $(out)'
-  '';
-
-  postInstall = ''
-    install -D -m0644 -t $out/share/doc COPYING README
-    mkdir -p $out/share/man; mv $out/man1 $out/share/man
-  '';
-
-  meta = with lib; {
-    description = "Simple program to detect bad disks by filling them with random data";
-    longDescription = ''
-      disk-filltest is a tool to check storage disks for coming
-      failures by write files with pseudo-random data to the current
-      directory until the disk is full, read the files again
-      and verify the sequence written. It also can measure
-      read/write speed while filling the disk.
-    '';
-    homepage = "https://panthema.net/2013/disk-filltest";
-    license = licenses.gpl3;
-    maintainers = with maintainers; [ caadar ];
-    platforms = platforms.all;
-    mainProgram = "disk-filltest";
-  };
-
-}

pkgs/top-level/all-packages.nix

@@ -3956,8 +3956,6 @@ with pkgs;
 
   glyr = callPackage ../tools/audio/glyr { };
 
-  gtklp = callPackage ../tools/misc/gtklp { };
-
   google-amber = callPackage ../tools/graphics/amber {
     inherit (darwin) cctools;
   };
@@ -5108,8 +5106,6 @@ with pkgs;
 
   disfetch = callPackage ../tools/misc/disfetch { };
 
-  disk-filltest = callPackage ../tools/system/disk-filltest { };
-
   disk-inventory-x = callPackage ../tools/filesystems/disk-inventory-x { };
 
   diskscan = callPackage ../tools/misc/diskscan { };
@@ -13370,8 +13366,6 @@ with pkgs;
 
   sqlboiler = callPackage ../development/tools/sqlboiler { };
 
-  ssh-askpass-fullscreen = callPackage ../tools/networking/ssh-askpass-fullscreen { };
-
   sshed = callPackage ../tools/networking/sshed { };
 
   sshguard = callPackage ../tools/security/sshguard { };