From 61aacee77d6c293d7e36e6655408479c5868360c Mon Sep 17 00:00:00 2001
From: figsoda <figsoda@pm.me>
Date: Sun, 4 Dec 2022 22:58:15 -0500
Subject: [PATCH] sniffnet: init at 1.0.1

---
 .../networking/sniffnet/default.nix           | 51 +++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  2 +
 2 files changed, 53 insertions(+)
 create mode 100644 pkgs/applications/networking/sniffnet/default.nix

diff --git a/pkgs/applications/networking/sniffnet/default.nix b/pkgs/applications/networking/sniffnet/default.nix
new file mode 100644
index 000000000000..6dc59e1432ab
--- /dev/null
+++ b/pkgs/applications/networking/sniffnet/default.nix
@@ -0,0 +1,51 @@
+{ lib
+, rustPlatform
+, fetchCrate
+, pkg-config
+, libpcap
+, stdenv
+, fontconfig
+, libGL
+, xorg
+, darwin
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "sniffnet";
+  version = "1.0.1";
+
+  src = fetchCrate {
+    inherit pname version;
+    sha256 = "sha256-8K774j04BOEuJjnFYjaSctPwBrKYYKqjFS2+PyxJ2FM=";
+  };
+
+  cargoSha256 = "sha256-096i4wDdoJCICd0L2QNY+7cKHQnijK22zj4XaQNuko8=";
+
+  nativeBuildInputs = [ pkg-config ];
+
+  buildInputs = [
+    libpcap
+  ] ++ lib.optionals stdenv.isLinux [
+    fontconfig
+    libGL
+    xorg.libX11
+    xorg.libXcursor
+    xorg.libXi
+    xorg.libXrandr
+  ] ++ lib.optionals stdenv.isDarwin [
+    darwin.apple_sdk.frameworks.AppKit
+  ];
+
+  postFixup = lib.optionalString stdenv.isLinux ''
+    patchelf $out/bin/sniffnet \
+      --add-rpath ${lib.makeLibraryPath [ libGL xorg.libX11 ]}
+  '';
+
+  meta = with lib; {
+    description = "Cross-platform application to monitor your network traffic with ease";
+    homepage = "https://github.com/gyulyvgc/sniffnet";
+    changelog = "https://github.com/gyulyvgc/sniffnet/blob/main/CHANGELOG.md";
+    license = with licenses; [ mit /* or */ asl20 ];
+    maintainers = with maintainers; [ figsoda ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index d8d21c8e8cba..7be967c8e35e 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -31942,6 +31942,8 @@ with pkgs;
 
   slrn = callPackage ../applications/networking/newsreaders/slrn { };
 
+  sniffnet = callPackage ../applications/networking/sniffnet { };
+
   sniproxy = callPackage ../applications/networking/sniproxy { };
 
   snixembed = callPackage ../applications/misc/snixembed { };