diff --git a/pkgs/by-name/ff/fflogs/package.nix b/pkgs/by-name/ff/fflogs/package.nix
new file mode 100644
index 000000000000..964805a549a5
--- /dev/null
+++ b/pkgs/by-name/ff/fflogs/package.nix
@@ -0,0 +1,37 @@
+{ lib
+, appimageTools
+, fetchurl
+}:
+
+let
+  pname = "fflogs";
+  version = "8.3.42";
+  src = fetchurl {
+    url = "https://github.com/RPGLogs/Uploaders-fflogs/releases/download/v${version}/fflogs-v${version}.AppImage";
+    hash = "sha256-Bc4C1cOOHdWkw2mHn3Q/2fcKuyCFDvOq1jLee2WPsyI=";
+  };
+  extracted = appimageTools.extractType2 { inherit pname version src; };
+in
+appimageTools.wrapType2 {
+  inherit pname version src;
+
+  extraInstallCommands = ''
+    mkdir -p $out/share/applications
+    cp -r ${extracted}/usr/share/icons $out/share/
+    chmod -R +w $out/share/
+    mv $out/share/icons/hicolor/0x0 $out/share/icons/hicolor/512x512 # https://github.com/electron-userland/electron-builder/issues/5294
+    cp ${extracted}/fflogs.desktop $out/share/applications/
+    sed -i 's@^Exec=AppRun --no-sandbox@Exec=fflogs@g' $out/share/applications/fflogs.desktop
+  '';
+
+  meta = with lib; {
+    description = "An application for uploading Final Fantasy XIV combat logs to fflogs.com";
+    homepage = "https://www.fflogs.com/client/download";
+    downloadPage = "https://github.com/RPGLogs/Uploaders-fflogs/releases/latest";
+    license = licenses.unfree; # no license listed
+    mainProgram = "fflogs";
+    platforms = platforms.linux;
+    maintainers = with maintainers; [ sersorrel ];
+    sourceProvenance = with sourceTypes; [ binaryNativeCode ];
+  };
+}