corsix-th: init at 0.66

pkgs/games/corsix-th/default.nix

@@ -0,0 +1,44 @@
+{ stdenv
+, lib
+, fetchFromGitHub
+, cmake
+, doxygen
+, ffmpeg
+, freetype
+, lua
+, makeWrapper
+, SDL2
+, SDL2_mixer
+, timidity
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "corsix-th";
+  version = "0.66";
+
+  src = fetchFromGitHub {
+    owner = "CorsixTH";
+    repo = "CorsixTH";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-GsZU2FHcFRlwN3hnFTyQmUK6kJLwnarKDtvg+DDc+mk=";
+  };
+
+  luaEnv = lua.withPackages(p: with p; [ luafilesystem lpeg luasec luasocket ]);
+  nativeBuildInputs = [ cmake doxygen makeWrapper ];
+  buildInputs = [ ffmpeg freetype lua finalAttrs.luaEnv SDL2 SDL2_mixer timidity ];
+  cmakeFlags = [ "-Wno-dev" ];
+
+  postInstall = ''
+    wrapProgram $out/bin/corsix-th \
+    --set LUA_PATH "$LUA_PATH" \
+    --set LUA_CPATH "$LUA_CPATH"
+  '';
+
+  meta = with lib; {
+    description = "A reimplementation of the 1997 Bullfrog business sim Theme Hospital.";
+    homepage = "https://corsixth.com/";
+    license = licenses.mit;
+    maintainers = with maintainers; [ hughobrien ];
+    platforms = platforms.linux;
+  };
+})

pkgs/top-level/all-packages.nix

@@ -36457,6 +36457,8 @@ with pkgs;
 
   colobot = callPackage ../games/colobot { };
 
+  corsix-th = callPackage ../games/corsix-th { };
+
   enigma = callPackage ../games/enigma { };
 
   everspace = callPackage ../games/everspace { };