From 66044f7e4384e12ffd68ce7d7372fcdcb528a358 Mon Sep 17 00:00:00 2001
From: figsoda <figsoda@pm.me>
Date: Mon, 3 Oct 2022 09:44:50 -0400
Subject: [PATCH] artem: init at 1.1.5

---
 pkgs/applications/graphics/artem/default.nix | 50 ++++++++++++++++++++
 pkgs/top-level/all-packages.nix              |  2 +
 2 files changed, 52 insertions(+)
 create mode 100644 pkgs/applications/graphics/artem/default.nix

diff --git a/pkgs/applications/graphics/artem/default.nix b/pkgs/applications/graphics/artem/default.nix
new file mode 100644
index 000000000000..5747c88b24bb
--- /dev/null
+++ b/pkgs/applications/graphics/artem/default.nix
@@ -0,0 +1,50 @@
+{ lib
+, rustPlatform
+, fetchFromGitHub
+, installShellFiles
+, pkg-config
+, openssl
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "artem";
+  version = "1.1.5";
+
+  src = fetchFromGitHub {
+    owner = "finefindus";
+    repo = pname;
+    rev = "v${version}";
+    sha256 = "1jax39gizlcbqnkjckxwm5h0wdk5dk8dasaj9wxv7yidbcbgj4zh";
+  };
+
+  cargoSha256 = "sha256-n2NOWrgcMVHpNCHL7r8+Kl1e01XYadaNM7UdE8fQo1U=";
+
+  nativeBuildInputs = [ installShellFiles pkg-config ];
+
+  buildInputs = [ openssl ];
+
+  OPENSSL_NO_VENDOR = 1;
+
+  checkFlags = [
+    # require internet access
+    "--skip=arguments::input::url_input"
+    "--skip=full_file_compare_url"
+
+    # flaky
+    "--skip=full_file_compare_html"
+  ];
+
+  postInstall = ''
+    installManPage $releaseDir/build/artem-*/out/artem.1
+    installShellCompletion $releaseDir/build/artem-*/out/artem.{bash,fish} \
+      --zsh $releaseDir/build/artem-*/out/_artem
+  '';
+
+  meta = with lib; {
+    description = "A small CLI program to convert images to ASCII art";
+    homepage = "https://github.com/finefindus/artem";
+    changelog = "https://github.com/finefindus/artem/blob/v${version}/CHANGELOG.md";
+    license = licenses.mpl20;
+    maintainers = with maintainers; [ figsoda ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 8a09bb50c797..0b39e510c7f4 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -26768,6 +26768,8 @@ with pkgs;
 
   arkade = callPackage ../applications/networking/cluster/arkade { };
 
+  artem = callPackage ../applications/graphics/artem { };
+
   asuka = callPackage ../applications/networking/browsers/asuka {
     inherit (darwin.apple_sdk.frameworks) Security;
   };