Merge pull request #272565 from benlemasurier/polybar-pulseaudio-control

polybar-pulseaudio-control: init at 3.1.1

maintainers/maintainer-list.nix

@@ -2268,6 +2268,15 @@
     githubId = 16821405;
     name = "Ben Kuhn";
   };
+  benlemasurier = {
+    email = "ben@crypt.ly";
+    github = "benlemasurier";
+    githubId = 47993;
+    name = "Ben LeMasurier";
+    keys = [{
+      fingerprint = "0FD4 7407 EFD4 8FD8 8BF5  87B3 248D 430A E8E7 4189";
+    }];
+  };
   benley = {
     email = "benley@gmail.com";
     github = "benley";

pkgs/by-name/po/polybar-pulseaudio-control/package.nix

@@ -0,0 +1,44 @@
+{ lib
+, bash
+, coreutils
+, fetchFromGitHub
+, gawk
+, makeWrapper
+, pulseaudio
+, stdenv
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "polybar-pulseaudio-control";
+  version = "3.1.1";
+
+  src = fetchFromGitHub {
+    owner = "marioortizmanero";
+    repo = "polybar-pulseaudio-control";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-egCBCnhnmHHKFeDkpaF9Upv/oZ0K3XGyutnp4slq9Vc=";
+  };
+
+  dontConfigure = true;
+  dontBuild = true;
+  nativeBuildInputs = [ makeWrapper ];
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm755 pulseaudio-control.bash $out/bin/pulseaudio-control
+    wrapProgram "$out/bin/pulseaudio-control" \
+      --prefix PATH : "${lib.makeBinPath [ bash coreutils gawk pulseaudio ]}"
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    mainProgram = "pulseaudio-control";
+    description = "Polybar module to control PulseAudio devices, also known as Pavolume";
+    homepage = "https://github.com/marioortizmanero/polybar-pulseaudio-control";
+    platforms = platforms.linux;
+    license = licenses.mit;
+    maintainers = with maintainers; [ benlemasurier ];
+  };
+})