From 9dc256099f3bc143cd44180775a03d1ac2ff83cc Mon Sep 17 00:00:00 2001
From: Andrew Cobb <andrew.cobb@gmail.com>
Date: Sat, 2 Sep 2017 09:11:10 -0400
Subject: [PATCH] kupfer: init at 319 (#28719)

* kupfer: init at 319

* kupfer: wrap with wrapGAppsHook

* kupfer: fixing up runtime dependencies

* kupfer: added cobbal as maintainer
---
 lib/maintainers.nix                       |  1 +
 pkgs/applications/misc/kupfer/default.nix | 66 +++++++++++++++++++++++
 pkgs/top-level/all-packages.nix           |  2 +
 3 files changed, 69 insertions(+)
 create mode 100644 pkgs/applications/misc/kupfer/default.nix

diff --git a/lib/maintainers.nix b/lib/maintainers.nix
index fbdeff3c073b..0859fba7b1d5 100644
--- a/lib/maintainers.nix
+++ b/lib/maintainers.nix
@@ -113,6 +113,7 @@
   cleverca22 = "Michael Bishop <cleverca22@gmail.com>";
   cmcdragonkai = "Roger Qiu <roger.qiu@matrix.ai>";
   cmfwyp = "cmfwyp <cmfwyp@riseup.net>";
+  cobbal = "Andrew Cobb <andrew.cobb@gmail.com>";
   coconnor = "Corey O'Connor <coreyoconnor@gmail.com>";
   codsl = "codsl <codsl@riseup.net>";
   codyopel = "Cody Opel <codyopel@gmail.com>";
diff --git a/pkgs/applications/misc/kupfer/default.nix b/pkgs/applications/misc/kupfer/default.nix
new file mode 100644
index 000000000000..f3bb825cbf74
--- /dev/null
+++ b/pkgs/applications/misc/kupfer/default.nix
@@ -0,0 +1,66 @@
+{ stdenv
+, makeWrapper
+, fetchurl
+, intltool
+, python3Packages
+, gtk3
+, dbus
+, libwnck3
+, keybinder3
+, hicolor_icon_theme
+, wrapGAppsHook
+}:
+
+with python3Packages;
+
+buildPythonApplication rec {
+  name = "kupfer-${version}";
+  version = "319";
+
+  src = fetchurl {
+    url = "https://github.com/kupferlauncher/kupfer/releases/download/v${version}/kupfer-v${version}.tar.xz";
+    sha256 = "0c9xjx13r8ckfr4az116bhxsd3pk78v04c3lz6lqhraak0rp4d92";
+  };
+
+  nativeBuildInputs = [ wrapGAppsHook intltool ];
+  buildInputs = [ hicolor_icon_theme docutils libwnck3 keybinder3 ];
+  propagatedBuildInputs = [ pygobject3 gtk3 pyxdg dbus-python pycairo ];
+
+  configurePhase = ''
+    runHook preConfigure
+    python ./waf configure --prefix=$prefix
+    runHook postConfigure
+  '';
+
+  buildPhase = ''
+    runHook preBuild
+    python ./waf
+    runHook postBuild
+  '';
+
+  installPhase = let
+    pythonPath = (stdenv.lib.concatMapStringsSep ":"
+      (m: "${m}/lib/${python.libPrefix}/site-packages")
+      propagatedBuildInputs);
+  in ''
+    runHook preInstall
+    python ./waf install
+
+    gappsWrapperArgs+=(
+      "--prefix" "PYTHONPATH" : "${pythonPath}"
+      "--set" "PYTHONNOUSERSITE" "1"
+    )
+
+    runHook postInstall
+  '';
+
+  doCheck = false; # no tests
+
+  meta = with stdenv.lib; {
+    description = "A smart, quick launcher";
+    homepage    = "https://kupferlauncher.github.io/";
+    license     = licenses.gpl3;
+    maintainers = with maintainers; [ cobbal ];
+    platforms   = platforms.linux;
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 6bbba06b9eeb..44f4c63bb23a 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -15038,6 +15038,8 @@ with pkgs;
     go = go_1_7;
   };
 
+  kupfer = callPackage ../applications/misc/kupfer { };
+
   lame = callPackage ../development/libraries/lame { };
 
   larswm = callPackage ../applications/window-managers/larswm { };