Merge pull request #300501 from fabaff/malwoverview

malwoverview: init at 5.4.2

pkgs/by-name/ma/malwoverview/package.nix

@@ -0,0 +1,57 @@
+{ lib
+, fetchFromGitHub
+, python3
+}:
+
+python3.pkgs.buildPythonApplication rec {
+  pname = "malwoverview";
+  version = "5.4.2";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "alexandreborges";
+    repo = "malwoverview";
+    rev = "refs/tags/v${version}";
+    hash = "sha256-WAlVEEukPOynCGpRdQu3wP+JZ1UKuSR6pH5ek81L73E=";
+  };
+
+  pythonRemoveDeps = [
+    "pathlib"
+  ];
+
+  nativeBuildInputs = with python3.pkgs; [
+    pythonRelaxDepsHook
+  ];
+
+  build-system  = with python3.pkgs; [
+    setuptools
+  ];
+
+  dependencies = with python3.pkgs; [
+    colorama
+    configparser
+    geocoder
+    pefile
+    polyswarm-api
+    python-magic
+    requests
+    simplejson
+    validators
+  ];
+
+  # Project has no tests
+  doCheck = false;
+
+  pythonImportsCheck = [
+    "malwoverview"
+  ];
+
+  meta = with lib; {
+    description = "Tool for threat hunting and gathering intel information from various sources";
+    homepage = "https://github.com/alexandreborges/malwoverview";
+    changelog = "https://github.com/alexandreborges/malwoverview/releases/tag/v${version}";
+    license = licenses.gpl3Only;
+    maintainers = with maintainers; [ fab ];
+    mainProgram = "malwoverview.py";
+  };
+}

pkgs/development/python-modules/geocoder/default.nix

@@ -0,0 +1,47 @@
+{ lib
+, buildPythonPackage
+, click
+, fetchPypi
+, future
+, pythonOlder
+, ratelim
+, requests
+, setuptools
+, six
+}:
+
+buildPythonPackage rec {
+  pname = "geocoder";
+  version = "1.38.1";
+  pyproject = true;
+
+  disabled = pythonOlder "3.7";
+
+  src = fetchPypi {
+    inherit pname version;
+    hash = "sha256-yZJTdMlhV30K7kA7Ceb46hlx2RPwEfAMpwx2vq96d+c=";
+  };
+
+  build-system = [
+    setuptools
+  ];
+
+  dependencies = [
+    click
+    future
+    ratelim
+    requests
+    six
+  ];
+
+  pythonImportsCheck = [
+    "geocoder"
+  ];
+
+  meta = with lib; {
+    description = "Module for geocoding";
+    homepage = "https://pypi.org/project/geocoder/";
+    license = licenses.mit;
+    maintainers = with maintainers; [ fab ];
+  };
+}

pkgs/development/python-modules/polyswarm-api/default.nix

@@ -0,0 +1,66 @@
+{ lib
+, buildPythonPackage
+, fetchFromGitHub
+, future
+, jsonschema
+, pytestCheckHook
+, python-dateutil
+, pythonOlder
+, pythonRelaxDepsHook
+, requests
+, responses
+, setuptools
+, vcrpy
+}:
+
+buildPythonPackage rec {
+  pname = "polyswarm-api";
+  version = "3.5.2";
+  pyproject = true;
+
+  disabled = pythonOlder "3.8";
+
+  src = fetchFromGitHub {
+    owner = "polyswarm";
+    repo = "polyswarm-api";
+    rev = "refs/tags/${version}";
+    hash = "sha256-GMLgph6mjDSDn2CCfeqcqFY2gjtziH4xVHJhYTGRYw8=";
+  };
+
+  pythonRelaxDeps = [
+    "future"
+  ];
+
+  nativeBuildInputs = [
+    pythonRelaxDepsHook
+  ];
+
+  build-system = [
+    setuptools
+  ];
+
+  dependencies = [
+    future
+    jsonschema
+    python-dateutil
+    requests
+  ];
+
+  nativeCheckInputs = [
+    pytestCheckHook
+    responses
+    vcrpy
+  ];
+
+  pythonImportsCheck = [
+    "polyswarm_api"
+  ];
+
+  meta = with lib; {
+    description = "Library to interface with the PolySwarm consumer APIs";
+    homepage = "https://github.com/polyswarm/polyswarm-api";
+    changelog = "https://github.com/polyswarm/polyswarm-api/releases/tag/${version}";
+    license = licenses.mit;
+    maintainers = with maintainers; [ fab ];
+  };
+}

pkgs/top-level/python-packages.nix

@@ -4653,6 +4653,8 @@ self: super: with self; {
 
   geocachingapi = callPackage ../development/python-modules/geocachingapi { };
 
+  geocoder = callPackage ../development/python-modules/geocoder { };
+
   geographiclib = callPackage ../development/python-modules/geographiclib { };
 
   geoip2 = callPackage ../development/python-modules/geoip2 { };
@@ -10085,6 +10087,8 @@ self: super: with self; {
 
   polygon3 = callPackage ../development/python-modules/polygon3 { };
 
+  polyswarm-api = callPackage ../development/python-modules/polyswarm-api { };
+
   pomegranate = callPackage ../development/python-modules/pomegranate { };
 
   pontos = callPackage ../development/python-modules/pontos { };