python3Packages.pwndbg: init at 2024.02.14

pkgs/development/python-modules/pwndbg/default.nix

@@ -0,0 +1,80 @@
+{ lib
+, stdenv
+, buildPythonPackage
+, fetchFromGitHub
+, capstone
+, future
+, ipython
+, psutil
+, pwntools
+, pycparser
+, pyelftools
+, pygments
+, requests
+, rpyc
+, sortedcontainers
+, tabulate
+, typing-extensions
+, unicorn
+, gdb-pt-dump
+, poetry-core
+, pythonRelaxDepsHook
+}:
+let
+  # The newest gdb-pt-dump is incompatible with pwndbg 2024.02.14.
+  # See https://github.com/martinradev/gdb-pt-dump/issues/29
+  gdb-pt-dump' = gdb-pt-dump.overrideAttrs (oldAttrs: {
+    version = "0-unstable-2023-11-11";
+
+    src = fetchFromGitHub {
+      inherit (oldAttrs.src) owner repo;
+      rev = "89ea252f6efc5d75eacca16fc17ff8966a389690";
+      hash = "sha256-i+SAcZ/kgfKstJnkyCVMh/lWtrJJOHTYoJH4tVfYHrE=";
+    };
+
+    # This revision relies on the package being imported from within GDB, which
+    # won't work with pythonImportsCheck.
+    pythonImportsCheck = [ ];
+  });
+in
+buildPythonPackage rec {
+  pname = "pwndbg";
+  version = "2024.02.14";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "pwndbg";
+    repo = "pwndbg";
+    rev = version;
+    hash = "sha256-/pDo2J5EtpWWCurD7H34AlTlQi7WziIRRxHxGm3K2yk=";
+  };
+
+  nativeBuildInputs = [ poetry-core pythonRelaxDepsHook ];
+  pythonRelaxDeps = true;
+
+  propagatedBuildInputs = [
+    capstone
+    future
+    ipython
+    psutil
+    pwntools
+    pycparser
+    pyelftools
+    pygments
+    requests
+    rpyc
+    sortedcontainers
+    tabulate
+    typing-extensions
+    unicorn
+    gdb-pt-dump'
+  ];
+
+  meta = {
+    description = "Exploit Development and Reverse Engineering with GDB Made Easy";
+    homepage = "https://pwndbg.re";
+    changelog = "https://github.com/pwndbg/pwndbg/releases/tag/${version}";
+    license = lib.licenses.mit;
+    maintainers = with lib.maintainers; [ msanft ];
+  };
+}

pkgs/top-level/python-packages.nix

@@ -4614,6 +4614,8 @@ self: super: with self; {
 
   gdata = callPackage ../development/python-modules/gdata { };
 
+  gdb-pt-dump = callPackage ../development/python-modules/gdb-pt-dump { };
+
   gdcm = toPythonModule (pkgs.gdcm.override {
     inherit (self) python;
     enablePython = true;
@@ -10393,6 +10395,8 @@ self: super: with self; {
 
   pwlf = callPackage ../development/python-modules/pwlf { };
 
+  pwndbg = callPackage ../development/python-modules/pwndbg { };
+
   pwntools = callPackage ../development/python-modules/pwntools {
     debugger = pkgs.gdb;
   };