![Andrew Marshall](/assets/img/avatar_default.png)
Basic headless render test for Eevee and Cycles CPU. Did this because I got a bit tired of testing render manually for both renderers (though it’s not that much work). Note that `render.threads` config is used only by Cycles. Using 1 thread chosen because it’s not meaningfully slower than more for this render, and it simplifies things to just pick 1 instead of making it dynamic. Have chosen 32 samples since it’s not meaningfully slower than 1 (even with `--cores 1`), and it’s not so small that maybe it’s not representative, and too-low a number and there are artifacts that may make it appear like something is broken. Cycles denoising needs openimagedenoise and is not currently included in aarch64 build.
242 lines
8.7 KiB
Nix
242 lines
8.7 KiB
Nix
{ config, stdenv, lib, fetchurl, fetchzip, boost, cmake, ffmpeg, gettext, glew
|
|
, ilmbase, libepoxy, libXi, libX11, libXext, libXrender
|
|
, libjpeg, libpng, libsamplerate, libsndfile
|
|
, libtiff, libwebp, libGLU, libGL, openal, opencolorio, openexr, openimagedenoise, openimageio, openjpeg, python310Packages
|
|
, openvdb, libXxf86vm, tbb, alembic
|
|
, zlib, zstd, fftw, opensubdiv, freetype, jemalloc, ocl-icd, addOpenGLRunpath
|
|
, jackaudioSupport ? false, libjack2
|
|
, cudaSupport ? config.cudaSupport, cudaPackages ? { }
|
|
, hipSupport ? false, hip # comes with a significantly larger closure size
|
|
, colladaSupport ? true, opencollada
|
|
, spaceNavSupport ? stdenv.isLinux, libspnav
|
|
, makeWrapper
|
|
, pugixml, llvmPackages, SDL, Cocoa, CoreGraphics, ForceFeedback, OpenAL, OpenGL
|
|
, waylandSupport ? stdenv.isLinux, pkg-config, wayland, wayland-protocols, libffi, libdecor, libxkbcommon, dbus
|
|
, potrace
|
|
, openxr-loader
|
|
, embree, gmp, libharu
|
|
, mesa
|
|
, runCommand
|
|
}:
|
|
|
|
let
|
|
python = python310Packages.python;
|
|
optix = fetchzip {
|
|
# url taken from the archlinux blender PKGBUILD
|
|
url = "https://developer.download.nvidia.com/redist/optix/v7.3/OptiX-7.3.0-Include.zip";
|
|
sha256 = "0max1j4822mchj0xpz9lqzh91zkmvsn4py0r174cvqfz8z8ykjk8";
|
|
};
|
|
|
|
in
|
|
stdenv.mkDerivation (finalAttrs: rec {
|
|
pname = "blender";
|
|
version = "3.6.3";
|
|
|
|
src = fetchurl {
|
|
url = "https://download.blender.org/source/${pname}-${version}.tar.xz";
|
|
hash = "sha256-iRIwPrvPHwiIxHr7hpmG6NjS/liJkxcAgrzlk8LEFPg=";
|
|
};
|
|
|
|
patches = [
|
|
./draco.patch
|
|
] ++ lib.optional stdenv.isDarwin ./darwin.patch;
|
|
|
|
nativeBuildInputs =
|
|
[ cmake makeWrapper python310Packages.wrapPython llvmPackages.llvm.dev
|
|
]
|
|
++ lib.optionals cudaSupport [ addOpenGLRunpath ]
|
|
++ lib.optionals waylandSupport [ pkg-config ];
|
|
buildInputs =
|
|
[ boost ffmpeg gettext glew ilmbase
|
|
freetype libjpeg libpng libsamplerate libsndfile libtiff libwebp
|
|
opencolorio openexr openimageio openjpeg python zlib zstd fftw jemalloc
|
|
alembic
|
|
(opensubdiv.override { inherit cudaSupport; })
|
|
tbb
|
|
gmp
|
|
pugixml
|
|
potrace
|
|
libharu
|
|
libepoxy
|
|
]
|
|
++ lib.optionals waylandSupport [
|
|
wayland wayland-protocols libffi libdecor libxkbcommon dbus
|
|
]
|
|
++ lib.optionals (!stdenv.isAarch64) [
|
|
openimagedenoise
|
|
embree
|
|
]
|
|
++ (if (!stdenv.isDarwin) then [
|
|
libXi libX11 libXext libXrender
|
|
libGLU libGL openal
|
|
libXxf86vm
|
|
openxr-loader
|
|
# OpenVDB currently doesn't build on darwin
|
|
openvdb
|
|
]
|
|
else [
|
|
llvmPackages.openmp SDL Cocoa CoreGraphics ForceFeedback OpenAL OpenGL
|
|
])
|
|
++ lib.optional jackaudioSupport libjack2
|
|
++ lib.optional cudaSupport cudaPackages.cudatoolkit
|
|
++ lib.optional colladaSupport opencollada
|
|
++ lib.optional spaceNavSupport libspnav;
|
|
pythonPath = with python310Packages; [ numpy requests zstandard ];
|
|
|
|
postPatch = ''
|
|
'' +
|
|
(if stdenv.isDarwin then ''
|
|
: > build_files/cmake/platform/platform_apple_xcode.cmake
|
|
substituteInPlace source/creator/CMakeLists.txt \
|
|
--replace '${"$"}{LIBDIR}/python' \
|
|
'${python}'
|
|
substituteInPlace build_files/cmake/platform/platform_apple.cmake \
|
|
--replace '${"$"}{LIBDIR}/python' \
|
|
'${python}' \
|
|
--replace '${"$"}{LIBDIR}/opencollada' \
|
|
'${opencollada}' \
|
|
--replace '${"$"}{PYTHON_LIBPATH}/site-packages/numpy' \
|
|
'${python310Packages.numpy}/${python.sitePackages}/numpy'
|
|
'' else ''
|
|
substituteInPlace extern/clew/src/clew.c --replace '"libOpenCL.so"' '"${ocl-icd}/lib/libOpenCL.so"'
|
|
'') +
|
|
(lib.optionalString hipSupport ''
|
|
substituteInPlace extern/hipew/src/hipew.c --replace '"/opt/rocm/hip/lib/libamdhip64.so"' '"${hip}/lib/libamdhip64.so"'
|
|
substituteInPlace extern/hipew/src/hipew.c --replace '"opt/rocm/hip/bin"' '"${hip}/bin"'
|
|
'');
|
|
|
|
cmakeFlags =
|
|
[
|
|
"-DWITH_ALEMBIC=ON"
|
|
# Blender supplies its own FindAlembic.cmake (incompatible with the Alembic-supplied config file)
|
|
"-DALEMBIC_INCLUDE_DIR=${lib.getDev alembic}/include"
|
|
"-DALEMBIC_LIBRARY=${lib.getLib alembic}/lib/libAlembic.so"
|
|
"-DWITH_MOD_OCEANSIM=ON"
|
|
"-DWITH_CODEC_FFMPEG=ON"
|
|
"-DWITH_CODEC_SNDFILE=ON"
|
|
"-DWITH_INSTALL_PORTABLE=OFF"
|
|
"-DWITH_FFTW3=ON"
|
|
"-DWITH_SDL=OFF"
|
|
"-DWITH_OPENCOLORIO=ON"
|
|
"-DWITH_OPENSUBDIV=ON"
|
|
"-DPYTHON_LIBRARY=${python.libPrefix}"
|
|
"-DPYTHON_LIBPATH=${python}/lib"
|
|
"-DPYTHON_INCLUDE_DIR=${python}/include/${python.libPrefix}"
|
|
"-DPYTHON_VERSION=${python.pythonVersion}"
|
|
"-DWITH_PYTHON_INSTALL=OFF"
|
|
"-DWITH_PYTHON_INSTALL_NUMPY=OFF"
|
|
"-DPYTHON_NUMPY_PATH=${python310Packages.numpy}/${python.sitePackages}"
|
|
"-DPYTHON_NUMPY_INCLUDE_DIRS=${python310Packages.numpy}/${python.sitePackages}/numpy/core/include"
|
|
"-DWITH_PYTHON_INSTALL_REQUESTS=OFF"
|
|
"-DWITH_OPENVDB=ON"
|
|
"-DWITH_TBB=ON"
|
|
"-DWITH_IMAGE_OPENJPEG=ON"
|
|
"-DWITH_OPENCOLLADA=${if colladaSupport then "ON" else "OFF"}"
|
|
]
|
|
++ lib.optionals waylandSupport [
|
|
"-DWITH_GHOST_WAYLAND=ON"
|
|
"-DWITH_GHOST_WAYLAND_DBUS=ON"
|
|
"-DWITH_GHOST_WAYLAND_DYNLOAD=OFF"
|
|
"-DWITH_GHOST_WAYLAND_LIBDECOR=ON"
|
|
]
|
|
++ lib.optionals stdenv.hostPlatform.isAarch64 [
|
|
"-DWITH_CYCLES_EMBREE=OFF"
|
|
]
|
|
++ lib.optionals stdenv.isDarwin [
|
|
"-DWITH_CYCLES_OSL=OFF" # requires LLVM
|
|
"-DWITH_OPENVDB=OFF" # OpenVDB currently doesn't build on darwin
|
|
|
|
"-DLIBDIR=/does-not-exist"
|
|
]
|
|
# Clang doesn't support "-export-dynamic"
|
|
++ lib.optional stdenv.cc.isClang "-DPYTHON_LINKFLAGS="
|
|
++ lib.optional jackaudioSupport "-DWITH_JACK=ON"
|
|
++ lib.optionals cudaSupport [
|
|
"-DWITH_CYCLES_CUDA_BINARIES=ON"
|
|
"-DWITH_CYCLES_DEVICE_OPTIX=ON"
|
|
"-DOPTIX_ROOT_DIR=${optix}"
|
|
];
|
|
|
|
env.NIX_CFLAGS_COMPILE = "-I${ilmbase.dev}/include/OpenEXR -I${python}/include/${python.libPrefix}";
|
|
|
|
# Since some dependencies are built with gcc 6, we need gcc 6's
|
|
# libstdc++ in our RPATH. Sigh.
|
|
NIX_LDFLAGS = lib.optionalString cudaSupport "-rpath ${stdenv.cc.cc.lib}/lib";
|
|
|
|
blenderExecutable =
|
|
placeholder "out" + (if stdenv.isDarwin then "/Applications/Blender.app/Contents/MacOS/Blender" else "/bin/blender");
|
|
postInstall = lib.optionalString stdenv.isDarwin ''
|
|
mkdir $out/Applications
|
|
mv $out/Blender.app $out/Applications
|
|
'' + ''
|
|
mv $out/share/blender/${lib.versions.majorMinor version}/python{,-ext}
|
|
buildPythonPath "$pythonPath"
|
|
wrapProgram $blenderExecutable \
|
|
--prefix PATH : $program_PATH \
|
|
--prefix PYTHONPATH : "$program_PYTHONPATH" \
|
|
--add-flags '--python-use-system-env'
|
|
'';
|
|
|
|
# Set RUNPATH so that libcuda and libnvrtc in /run/opengl-driver(-32)/lib can be
|
|
# found. See the explanation in libglvnd.
|
|
postFixup = lib.optionalString cudaSupport ''
|
|
for program in $out/bin/blender $out/bin/.blender-wrapped; do
|
|
isELF "$program" || continue
|
|
addOpenGLRunpath "$program"
|
|
done
|
|
'';
|
|
|
|
passthru = {
|
|
inherit python;
|
|
|
|
tests = {
|
|
render = runCommand "${pname}-test" { } ''
|
|
set -euo pipefail
|
|
|
|
export LIBGL_DRIVERS_PATH=${mesa.drivers}/lib/dri
|
|
export __EGL_VENDOR_LIBRARY_FILENAMES=${mesa.drivers}/share/glvnd/egl_vendor.d/50_mesa.json
|
|
|
|
cat <<'PYTHON' > scene-config.py
|
|
import bpy
|
|
bpy.context.scene.eevee.taa_render_samples = 32
|
|
bpy.context.scene.cycles.samples = 32
|
|
if ${if stdenv.isAarch64 then "True" else "False"}:
|
|
bpy.context.scene.cycles.use_denoising = False
|
|
bpy.context.scene.render.resolution_x = 100
|
|
bpy.context.scene.render.resolution_y = 100
|
|
bpy.context.scene.render.threads_mode = 'FIXED'
|
|
bpy.context.scene.render.threads = 1
|
|
PYTHON
|
|
|
|
mkdir $out
|
|
for engine in BLENDER_EEVEE CYCLES; do
|
|
echo "Rendering with $engine..."
|
|
# Beware that argument order matters
|
|
${finalAttrs.finalPackage}/bin/blender \
|
|
--background \
|
|
-noaudio \
|
|
--factory-startup \
|
|
--python-exit-code 1 \
|
|
--python scene-config.py \
|
|
--engine "$engine" \
|
|
--render-output "$out/$engine" \
|
|
--render-frame 1
|
|
done
|
|
'';
|
|
};
|
|
};
|
|
|
|
meta = with lib; {
|
|
description = "3D Creation/Animation/Publishing System";
|
|
homepage = "https://www.blender.org";
|
|
# They comment two licenses: GPLv2 and Blender License, but they
|
|
# say: "We've decided to cancel the BL offering for an indefinite period."
|
|
# OptiX, enabled with cudaSupport, is non-free.
|
|
license = with licenses; [ gpl2Plus ] ++ optional cudaSupport unfree;
|
|
platforms = [ "x86_64-linux" "x86_64-darwin" "aarch64-linux" ];
|
|
broken = stdenv.isDarwin;
|
|
maintainers = with maintainers; [ goibhniu veprbl ];
|
|
mainProgram = "blender";
|
|
};
|
|
})
|