b8698cd8d6
Closes #193336 Closes #261694 Related to #108984 The goal here was to get the following flake to build and run on `aarch64-darwin`: ```nix { inputs.nixpkgs.url = <this branch>; outputs = { nixpkgs, ... }: { checks.aarch64-darwin.default = nixpkgs.legacyPackages.aarch64-darwin.nixosTest { name = "test"; nodes.machine = { }; testScript = ""; }; }; } ``` … and after this change it does. There's no longer a need for the user to set `nodes.*.nixpkgs.pkgs` or `nodes.*.virtualisation.host.pkgs` as the correct values are inferred from the host system.
70 lines
2.1 KiB
Nix
70 lines
2.1 KiB
Nix
{ config, hostPkgs, lib, ... }:
|
|
let
|
|
inherit (lib) types mkOption mdDoc;
|
|
in
|
|
{
|
|
options = {
|
|
passthru = mkOption {
|
|
type = types.lazyAttrsOf types.raw;
|
|
description = mdDoc ''
|
|
Attributes to add to the returned derivations,
|
|
which are not necessarily part of the build.
|
|
|
|
This is a bit like doing `drv // { myAttr = true; }` (which would be lost by `overrideAttrs`).
|
|
It does not change the actual derivation, but adds the attribute nonetheless, so that
|
|
consumers of what would be `drv` have more information.
|
|
'';
|
|
};
|
|
|
|
rawTestDerivation = mkOption {
|
|
type = types.package;
|
|
description = mdDoc ''
|
|
Unfiltered version of `test`, for troubleshooting the test framework and `testBuildFailure` in the test framework's test suite.
|
|
This is not intended for general use. Use `test` instead.
|
|
'';
|
|
internal = true;
|
|
};
|
|
|
|
test = mkOption {
|
|
type = types.package;
|
|
# TODO: can the interactive driver be configured to access the network?
|
|
description = mdDoc ''
|
|
Derivation that runs the test as its "build" process.
|
|
|
|
This implies that NixOS tests run isolated from the network, making them
|
|
more dependable.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = {
|
|
rawTestDerivation = hostPkgs.stdenv.mkDerivation {
|
|
name = "vm-test-run-${config.name}";
|
|
|
|
requiredSystemFeatures = [ "nixos-test" ]
|
|
++ lib.optionals hostPkgs.stdenv.hostPlatform.isLinux [ "kvm" ]
|
|
++ lib.optionals hostPkgs.stdenv.hostPlatform.isDarwin [ "apple-virt" ];
|
|
|
|
buildCommand = ''
|
|
mkdir -p $out
|
|
|
|
# effectively mute the XMLLogger
|
|
export LOGFILE=/dev/null
|
|
|
|
${config.driver}/bin/nixos-test-driver -o $out
|
|
'';
|
|
|
|
passthru = config.passthru;
|
|
|
|
meta = config.meta;
|
|
};
|
|
test = lib.lazyDerivation { # lazyDerivation improves performance when only passthru items and/or meta are used.
|
|
derivation = config.rawTestDerivation;
|
|
inherit (config) passthru meta;
|
|
};
|
|
|
|
# useful for inspection (debugging / exploration)
|
|
passthru.config = config;
|
|
};
|
|
}
|