2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
116 lines
4.4 KiB
Nix
116 lines
4.4 KiB
Nix
{ config, lib, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.programs.chromium;
|
|
|
|
defaultProfile = filterAttrs (k: v: v != null) {
|
|
HomepageLocation = cfg.homepageLocation;
|
|
DefaultSearchProviderEnabled = cfg.defaultSearchProviderEnabled;
|
|
DefaultSearchProviderSearchURL = cfg.defaultSearchProviderSearchURL;
|
|
DefaultSearchProviderSuggestURL = cfg.defaultSearchProviderSuggestURL;
|
|
ExtensionInstallForcelist = cfg.extensions;
|
|
};
|
|
in
|
|
|
|
{
|
|
###### interface
|
|
|
|
options = {
|
|
programs.chromium = {
|
|
enable = mkEnableOption "<command>chromium</command> policies";
|
|
|
|
extensions = mkOption {
|
|
type = types.listOf types.str;
|
|
description = lib.mdDoc ''
|
|
List of chromium extensions to install.
|
|
For list of plugins ids see id in url of extensions on
|
|
[chrome web store](https://chrome.google.com/webstore/category/extensions)
|
|
page. To install a chromium extension not included in the chrome web
|
|
store, append to the extension id a semicolon ";" followed by a URL
|
|
pointing to an Update Manifest XML file. See
|
|
[ExtensionInstallForcelist](https://cloud.google.com/docs/chrome-enterprise/policies/?policy=ExtensionInstallForcelist)
|
|
for additional details.
|
|
'';
|
|
default = [];
|
|
example = literalExpression ''
|
|
[
|
|
"chlffgpmiacpedhhbkiomidkjlcfhogd" # pushbullet
|
|
"mbniclmhobmnbdlbpiphghaielnnpgdp" # lightshot
|
|
"gcbommkclmclpchllfjekcdonpmejbdp" # https everywhere
|
|
"cjpalhdlnbpafiamejdnhcphjbkeiagm" # ublock origin
|
|
]
|
|
'';
|
|
};
|
|
|
|
homepageLocation = mkOption {
|
|
type = types.nullOr types.str;
|
|
description = lib.mdDoc "Chromium default homepage";
|
|
default = null;
|
|
example = "https://nixos.org";
|
|
};
|
|
|
|
defaultSearchProviderEnabled = mkOption {
|
|
type = types.nullOr types.bool;
|
|
description = lib.mdDoc "Enable the default search provider.";
|
|
default = null;
|
|
example = true;
|
|
};
|
|
|
|
defaultSearchProviderSearchURL = mkOption {
|
|
type = types.nullOr types.str;
|
|
description = lib.mdDoc "Chromium default search provider url.";
|
|
default = null;
|
|
example =
|
|
"https://encrypted.google.com/search?q={searchTerms}&{google:RLZ}{google:originalQueryForSuggestion}{google:assistedQueryStats}{google:searchFieldtrialParameter}{google:searchClient}{google:sourceId}{google:instantExtendedEnabledParameter}ie={inputEncoding}";
|
|
};
|
|
|
|
defaultSearchProviderSuggestURL = mkOption {
|
|
type = types.nullOr types.str;
|
|
description = lib.mdDoc "Chromium default search provider url for suggestions.";
|
|
default = null;
|
|
example =
|
|
"https://encrypted.google.com/complete/search?output=chrome&q={searchTerms}";
|
|
};
|
|
|
|
extraOpts = mkOption {
|
|
type = types.attrs;
|
|
description = ''
|
|
Extra chromium policy options. A list of available policies
|
|
can be found in the Chrome Enterprise documentation:
|
|
<link xlink:href="https://cloud.google.com/docs/chrome-enterprise/policies/">https://cloud.google.com/docs/chrome-enterprise/policies/</link>
|
|
Make sure the selected policy is supported on Linux and your browser version.
|
|
'';
|
|
default = {};
|
|
example = literalExpression ''
|
|
{
|
|
"BrowserSignin" = 0;
|
|
"SyncDisabled" = true;
|
|
"PasswordManagerEnabled" = false;
|
|
"SpellcheckEnabled" = true;
|
|
"SpellcheckLanguage" = [
|
|
"de"
|
|
"en-US"
|
|
];
|
|
}
|
|
'';
|
|
};
|
|
};
|
|
};
|
|
|
|
###### implementation
|
|
|
|
config = lib.mkIf cfg.enable {
|
|
# for chromium
|
|
environment.etc."chromium/policies/managed/default.json".text = builtins.toJSON defaultProfile;
|
|
environment.etc."chromium/policies/managed/extra.json".text = builtins.toJSON cfg.extraOpts;
|
|
# for google-chrome https://www.chromium.org/administrators/linux-quick-start
|
|
environment.etc."opt/chrome/policies/managed/default.json".text = builtins.toJSON defaultProfile;
|
|
environment.etc."opt/chrome/policies/managed/extra.json".text = builtins.toJSON cfg.extraOpts;
|
|
# for brave
|
|
environment.etc."brave/policies/managed/default.json".text = builtins.toJSON defaultProfile;
|
|
environment.etc."brave/policies/managed/extra.json".text = builtins.toJSON cfg.extraOpts;
|
|
};
|
|
}
|