2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
101 lines
2.6 KiB
Nix
101 lines
2.6 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.services.monetdb;
|
|
|
|
in {
|
|
meta.maintainers = with maintainers; [ StillerHarpo primeos ];
|
|
|
|
###### interface
|
|
options = {
|
|
services.monetdb = {
|
|
|
|
enable = mkEnableOption "the MonetDB database server";
|
|
|
|
package = mkOption {
|
|
type = types.package;
|
|
default = pkgs.monetdb;
|
|
defaultText = literalExpression "pkgs.monetdb";
|
|
description = lib.mdDoc "MonetDB package to use.";
|
|
};
|
|
|
|
user = mkOption {
|
|
type = types.str;
|
|
default = "monetdb";
|
|
description = lib.mdDoc "User account under which MonetDB runs.";
|
|
};
|
|
|
|
group = mkOption {
|
|
type = types.str;
|
|
default = "monetdb";
|
|
description = lib.mdDoc "Group under which MonetDB runs.";
|
|
};
|
|
|
|
dataDir = mkOption {
|
|
type = types.path;
|
|
default = "/var/lib/monetdb";
|
|
description = lib.mdDoc "Data directory for the dbfarm.";
|
|
};
|
|
|
|
port = mkOption {
|
|
type = types.ints.u16;
|
|
default = 50000;
|
|
description = lib.mdDoc "Port to listen on.";
|
|
};
|
|
|
|
listenAddress = mkOption {
|
|
type = types.str;
|
|
default = "127.0.0.1";
|
|
example = "0.0.0.0";
|
|
description = lib.mdDoc "Address to listen on.";
|
|
};
|
|
};
|
|
};
|
|
|
|
###### implementation
|
|
config = mkIf cfg.enable {
|
|
|
|
users.users.monetdb = mkIf (cfg.user == "monetdb") {
|
|
uid = config.ids.uids.monetdb;
|
|
group = cfg.group;
|
|
description = "MonetDB user";
|
|
home = cfg.dataDir;
|
|
createHome = true;
|
|
};
|
|
|
|
users.groups.monetdb = mkIf (cfg.group == "monetdb") {
|
|
gid = config.ids.gids.monetdb;
|
|
members = [ cfg.user ];
|
|
};
|
|
|
|
environment.systemPackages = [ cfg.package ];
|
|
|
|
systemd.services.monetdb = {
|
|
description = "MonetDB database server";
|
|
wantedBy = [ "multi-user.target" ];
|
|
after = [ "network.target" ];
|
|
path = [ cfg.package ];
|
|
unitConfig.RequiresMountsFor = "${cfg.dataDir}";
|
|
serviceConfig = {
|
|
User = cfg.user;
|
|
Group = cfg.group;
|
|
ExecStart = "${cfg.package}/bin/monetdbd start -n ${cfg.dataDir}";
|
|
ExecStop = "${cfg.package}/bin/monetdbd stop ${cfg.dataDir}";
|
|
};
|
|
preStart = ''
|
|
if [ ! -e ${cfg.dataDir}/.merovingian_properties ]; then
|
|
# Create the dbfarm (as cfg.user)
|
|
${cfg.package}/bin/monetdbd create ${cfg.dataDir}
|
|
fi
|
|
|
|
# Update the properties
|
|
${cfg.package}/bin/monetdbd set port=${toString cfg.port} ${cfg.dataDir}
|
|
${cfg.package}/bin/monetdbd set listenaddr=${cfg.listenAddress} ${cfg.dataDir}
|
|
'';
|
|
};
|
|
|
|
};
|
|
}
|