107 lines
3.6 KiB
Nix
107 lines
3.6 KiB
Nix
{ branch ? "stable", callPackage, fetchurl, lib, stdenv }:
|
|
let
|
|
versions =
|
|
if stdenv.isLinux then {
|
|
stable = "0.0.39";
|
|
ptb = "0.0.64";
|
|
canary = "0.0.235";
|
|
development = "0.0.7";
|
|
} else {
|
|
stable = "0.0.290";
|
|
ptb = "0.0.93";
|
|
canary = "0.0.379";
|
|
development = "0.0.17";
|
|
};
|
|
version = versions.${branch};
|
|
srcs = rec {
|
|
x86_64-linux = {
|
|
stable = fetchurl {
|
|
url = "https://dl.discordapp.net/apps/linux/${version}/discord-${version}.tar.gz";
|
|
hash = "sha256-KZLKBzd9hdOQkp7mN0rUZ8TbMvH2G0/AfwHPLAlDpug=";
|
|
};
|
|
ptb = fetchurl {
|
|
url = "https://dl-ptb.discordapp.net/apps/linux/${version}/discord-ptb-${version}.tar.gz";
|
|
hash = "sha256-loA/RdT6Y5c6Upius+vO/383FrutsJEYS/1uiR0gfqo=";
|
|
};
|
|
canary = fetchurl {
|
|
url = "https://dl-canary.discordapp.net/apps/linux/${version}/discord-canary-${version}.tar.gz";
|
|
hash = "sha256-FRRTI6CHcJQW+fwOEOScQb4C5ADoONtckrrQHWyJass=";
|
|
};
|
|
development = fetchurl {
|
|
url = "https://dl-development.discordapp.net/apps/linux/${version}/discord-development-${version}.tar.gz";
|
|
hash = "sha256-0XR6c1ratEQARXgNTbc6KBKBvZ9P+RL6m8RkmWW9dtE=";
|
|
};
|
|
};
|
|
x86_64-darwin = {
|
|
stable = fetchurl {
|
|
url = "https://dl.discordapp.net/apps/osx/${version}/Discord.dmg";
|
|
hash = "sha256-Y3Gp/4aaJc1JAPgknYAoTC5NaquWg/KFk4Iw+yg5bxU=";
|
|
};
|
|
ptb = fetchurl {
|
|
url = "https://dl-ptb.discordapp.net/apps/osx/${version}/DiscordPTB.dmg";
|
|
hash = "sha256-FEoxNiqDz0OivDoJzX1wnr69cJhz53sg7nb4iqiS1uQ=";
|
|
};
|
|
canary = fetchurl {
|
|
url = "https://dl-canary.discordapp.net/apps/osx/${version}/DiscordCanary.dmg";
|
|
hash = "sha256-iglS02KIcpgZIDx514QzEhqwT55XOPU+8aW0HSrjYCQ=";
|
|
};
|
|
development = fetchurl {
|
|
url = "https://dl-development.discordapp.net/apps/osx/${version}/DiscordDevelopment.dmg";
|
|
hash = "sha256-A8Dg1r7iGJyfB6VgzpyZj1CogPwQgZ3aMIKUoN0WlbY=";
|
|
};
|
|
};
|
|
aarch64-darwin = x86_64-darwin;
|
|
};
|
|
src = srcs.${stdenv.hostPlatform.system}.${branch};
|
|
|
|
meta = with lib; {
|
|
description = "All-in-one cross-platform voice and text chat for gamers";
|
|
homepage = "https://discordapp.com/";
|
|
downloadPage = "https://discordapp.com/download";
|
|
sourceProvenance = with sourceTypes; [ binaryNativeCode ];
|
|
license = licenses.unfree;
|
|
maintainers = with maintainers; [ MP2E Scrumplex artturin infinidoge jopejoe1 ];
|
|
platforms = [ "x86_64-linux" "x86_64-darwin" "aarch64-darwin" ];
|
|
mainProgram = "discord";
|
|
};
|
|
package =
|
|
if stdenv.isLinux
|
|
then ./linux.nix
|
|
else ./darwin.nix;
|
|
|
|
openasar = callPackage ./openasar.nix { };
|
|
|
|
packages = (
|
|
builtins.mapAttrs
|
|
(_: value:
|
|
callPackage package (value
|
|
// {
|
|
inherit src version openasar branch;
|
|
meta = meta // { mainProgram = value.binaryName; };
|
|
}))
|
|
{
|
|
stable = rec {
|
|
pname = "discord";
|
|
binaryName = "Discord";
|
|
desktopName = "Discord";
|
|
};
|
|
ptb = rec {
|
|
pname = "discord-ptb";
|
|
binaryName = if stdenv.isLinux then "DiscordPTB" else desktopName;
|
|
desktopName = "Discord PTB";
|
|
};
|
|
canary = rec {
|
|
pname = "discord-canary";
|
|
binaryName = if stdenv.isLinux then "DiscordCanary" else desktopName;
|
|
desktopName = "Discord Canary";
|
|
};
|
|
development = rec {
|
|
pname = "discord-development";
|
|
binaryName = if stdenv.isLinux then "DiscordDevelopment" else desktopName;
|
|
desktopName = "Discord Development";
|
|
};
|
|
}
|
|
);
|
|
in
|
|
packages.${branch}
|