4535b714c6
* graphicsmagick: adopt and refactor - finalAttrs design pattern - split man output - rename patches - update link that explains the patch * graphicsmagick-imagemagick-compat: rename filename * graphicsmagick-imagemagick-compat: hide it inside graphicsmagick.passthru * graphicsmagick-imagemagick-compat: refactor - use stdenvNoCC (since no compiler is called) - split man output - do not expose attributes - set `dontBuild = true` instead of using a fake `buildPhase` - install the artifacts via an elegant but questionable, Lispy dark magic * graphicsmagick: migrate to by-name * graphicsmagick: 1.3.42 -> 1.3.43 Co-authored-by: R. Ryantm <ryantm-bot@ryantm.com> * graphicsmagick: remove patch Since the security breach was solved upstream. --------- Co-authored-by: R. Ryantm <ryantm-bot@ryantm.com>
106 lines
2.5 KiB
Nix
106 lines
2.5 KiB
Nix
{ lib
|
|
, bzip2
|
|
, callPackage
|
|
, coreutils
|
|
, fetchurl
|
|
, fixDarwinDylibNames
|
|
, freetype
|
|
, ghostscript
|
|
, graphviz
|
|
, libX11
|
|
, libjpeg
|
|
, libpng
|
|
, libtiff
|
|
, libtool
|
|
, libwebp
|
|
, libxml2
|
|
, nukeReferences
|
|
, quantumdepth ? 8
|
|
, runCommand
|
|
, stdenv
|
|
, xz
|
|
, zlib
|
|
}:
|
|
|
|
stdenv.mkDerivation (finalAttrs: {
|
|
pname = "graphicsmagick";
|
|
version = "1.3.43";
|
|
|
|
src = fetchurl {
|
|
url = "mirror://sourceforge/graphicsmagick/GraphicsMagick-${finalAttrs.version}.tar.xz";
|
|
hash = "sha256-K4hYBzLNfkCdniLGEWI4vvSuBvzaEUUb8z0ln5y/OZ8=";
|
|
};
|
|
|
|
outputs = [ "out" "man" ];
|
|
|
|
buildInputs = [
|
|
bzip2
|
|
freetype
|
|
ghostscript
|
|
graphviz
|
|
libX11
|
|
libjpeg
|
|
libpng
|
|
libtiff
|
|
libtool
|
|
libwebp
|
|
libxml2
|
|
zlib
|
|
];
|
|
|
|
nativeBuildInputs = [
|
|
nukeReferences
|
|
xz
|
|
] ++ lib.optionals stdenv.hostPlatform.isDarwin [ fixDarwinDylibNames ];
|
|
|
|
configureFlags = [
|
|
# specify delegates explicitly otherwise `gm` will invoke the build
|
|
# coreutils for filetypes it doesn't natively support.
|
|
"MVDelegate=${lib.getExe' coreutils "mv"}"
|
|
(lib.enableFeature true "shared")
|
|
(lib.withFeature true "frozenpaths")
|
|
(lib.withFeatureAs true "quantum-depth" (toString quantumdepth))
|
|
(lib.withFeatureAs true "gslib" "yes")
|
|
];
|
|
|
|
# Remove CFLAGS from the binaries to avoid closure bloat.
|
|
# In the past we have had -dev packages in the closure of the binaries soley
|
|
# due to the string references.
|
|
postConfigure = ''
|
|
nuke-refs -e $out ./magick/magick_config.h
|
|
'';
|
|
|
|
postInstall = ''
|
|
sed -i 's/-ltiff.*'\'/\'/ $out/bin/*
|
|
'';
|
|
|
|
passthru = {
|
|
imagemagick-compat = callPackage ./imagemagick-compat.nix {
|
|
graphicsmagick = finalAttrs.finalPackage;
|
|
};
|
|
tests = {
|
|
issue-157920 = runCommand "issue-157920-regression-test" {
|
|
buildInputs = [ finalAttrs.finalPackage ];
|
|
} ''
|
|
gm convert ${graphviz}/share/doc/graphviz/neatoguide.pdf jpg:$out
|
|
'';
|
|
};
|
|
};
|
|
|
|
meta = {
|
|
homepage = "http://www.graphicsmagick.org";
|
|
description = "Swiss army knife of image processing";
|
|
longDescription = ''
|
|
GraphicsMagick is the swiss army knife of image processing, providing a
|
|
robust and efficient collection of tools and libraries which support
|
|
reading, writing, and manipulating an image in over 92 major formats
|
|
including important formats like DPX, GIF, JPEG, JPEG-2000, JXL, PNG, PDF,
|
|
PNM, TIFF, and WebP.
|
|
'';
|
|
license = with lib.licenses; [ mit ];
|
|
maintainers = with lib.maintainers; [ AndersonTorres ];
|
|
mainProgram = "gm";
|
|
platforms = lib.platforms.all;
|
|
};
|
|
})
|