6e465f4550
Mostly removes unnecessary use of `extraPkgs = pkgs: appimageTools.defaultFhsEnvArgs.multiPkgs pkgs;` This caused some packages to be listed twice. Also, fix some styling, and accidental use of top-level packages (sometimes due to the `with;` keyword, e.g. on `beeper`). Remove inclusions of `bash`, since `bashInteractive` is already present by default.
44 lines
1.5 KiB
Nix
44 lines
1.5 KiB
Nix
{ lib, appimageTools, fetchurl, asar }: let
|
|
pname = "todoist-electron";
|
|
version = "8.10.1";
|
|
|
|
src = fetchurl {
|
|
url = "https://electron-dl.todoist.com/linux/Todoist-linux-x86_64-${version}.AppImage";
|
|
hash = "sha256-Yp4wfibymHLGlaPDzu2rhSXxanwdXoNpF/d6+S0r+1U=";
|
|
};
|
|
|
|
appimageContents = (appimageTools.extract { inherit pname version src; }).overrideAttrs (oA: {
|
|
buildCommand = ''
|
|
${oA.buildCommand}
|
|
|
|
# Get rid of the autoupdater
|
|
${asar}/bin/asar extract $out/resources/app.asar app
|
|
sed -i 's/async isUpdateAvailable.*/async isUpdateAvailable(updateInfo) { return false;/g' app/node_modules/electron-updater/out/AppUpdater.js
|
|
${asar}/bin/asar pack app $out/resources/app.asar
|
|
'';
|
|
});
|
|
|
|
in appimageTools.wrapAppImage {
|
|
inherit pname version;
|
|
src = appimageContents;
|
|
|
|
extraPkgs = pkgs: [ pkgs.hidapi ];
|
|
|
|
extraInstallCommands = ''
|
|
# Add desktop convencience stuff
|
|
install -Dm444 ${appimageContents}/todoist.desktop -t $out/share/applications
|
|
install -Dm444 ${appimageContents}/todoist.png -t $out/share/pixmaps
|
|
substituteInPlace $out/share/applications/todoist.desktop \
|
|
--replace 'Exec=AppRun' "Exec=$out/bin/${pname} --"
|
|
'';
|
|
|
|
meta = with lib; {
|
|
homepage = "https://todoist.com";
|
|
description = "The official Todoist electron app";
|
|
platforms = [ "x86_64-linux" ];
|
|
license = licenses.unfree;
|
|
maintainers = with maintainers; [ kylesferrazza pokon548 ];
|
|
mainProgram = "todoist-electron";
|
|
};
|
|
}
|