4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
72 lines
1.8 KiB
Nix
72 lines
1.8 KiB
Nix
{lib, stdenv, python3Packages, fetchpatch, gettext, qt5, fetchFromGitHub}:
|
|
|
|
python3Packages.buildPythonApplication rec {
|
|
pname = "dupeguru";
|
|
version = "4.0.4";
|
|
|
|
format = "other";
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "arsenetar";
|
|
repo = "dupeguru";
|
|
rev = version;
|
|
sha256 = "0ma4f1c6vmpz8gi4sdy43x1ik7wh42wayvk1iq520d3i714kfcpy";
|
|
fetchSubmodules = true;
|
|
};
|
|
|
|
patches = [
|
|
# already merged to master, remove next version bump
|
|
(fetchpatch {
|
|
name = "remove-m-from-so-var.patch";
|
|
url = "https://github.com/arsenetar/dupeguru/commit/bd0f53bcbe463c48fe141b73af13542da36d82ba.patch";
|
|
sha256 = "07iisz8kcr7v8lb21inzj1avlpfhh9k8wcivbd33w49cr3mmnr26";
|
|
})
|
|
];
|
|
|
|
nativeBuildInputs = [
|
|
gettext
|
|
python3Packages.pyqt5
|
|
qt5.wrapQtAppsHook
|
|
];
|
|
|
|
pythonPath = with python3Packages; [
|
|
pyqt5
|
|
send2trash
|
|
sphinx
|
|
polib
|
|
hsaudiotag3k
|
|
];
|
|
|
|
makeFlags = [
|
|
"PREFIX=${placeholder ''out''}"
|
|
"NO_VENV=1"
|
|
];
|
|
|
|
# TODO: package pytest-monkeyplus for running tests
|
|
# https://github.com/NixOS/nixpkgs/pull/75054/files#r357690123
|
|
doCheck = false;
|
|
|
|
# Avoid double wrapping Python programs.
|
|
dontWrapQtApps = true;
|
|
|
|
# TODO: A bug in python wrapper
|
|
# see https://github.com/NixOS/nixpkgs/pull/75054#discussion_r357656916
|
|
preFixup = ''
|
|
makeWrapperArgs="''${qtWrapperArgs[@]}"
|
|
'';
|
|
|
|
# Executable in $out/bin is a symlink to $out/share/dupeguru/run.py
|
|
# so wrapPythonPrograms hook does not handle it automatically.
|
|
postFixup = ''
|
|
wrapPythonProgramsIn "$out/share/dupeguru" "$out $pythonPath"
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "GUI tool to find duplicate files in a system";
|
|
homepage = "https://github.com/arsenetar/dupeguru";
|
|
license = licenses.bsd3;
|
|
platforms = platforms.linux;
|
|
maintainers = [ maintainers.novoxudonoser ];
|
|
};
|
|
}
|