4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
60 lines
1.7 KiB
Nix
60 lines
1.7 KiB
Nix
{ lib, stdenv, fetchurl, makeDesktopItem, makeWrapper, unzip, mono6 }:
|
|
|
|
let
|
|
pname = "mission-planner";
|
|
desktopItem = makeDesktopItem {
|
|
name = pname;
|
|
exec = pname;
|
|
icon = pname;
|
|
comment = "MissionPlanner GCS & Ardupilot configuration tool";
|
|
desktopName = "MissionPlanner";
|
|
genericName = "Ground Control Station";
|
|
};
|
|
in stdenv.mkDerivation rec {
|
|
inherit pname;
|
|
version = "1.3.74";
|
|
|
|
src = fetchurl {
|
|
url = "https://firmware.ardupilot.org/Tools/MissionPlanner/MissionPlanner-${version}.zip";
|
|
sha256 = "1cgpmsmmnbzw1lwsdafp8yklk1rwc61yf12vc1ahcc6bl7q2385x";
|
|
};
|
|
|
|
nativeBuildInputs = [ makeWrapper mono6 unzip ];
|
|
sourceRoot = ".";
|
|
|
|
AOT_FILES = [ "MissionPlanner.exe" "MissionPlanner.*.dll" ];
|
|
|
|
buildPhase = ''
|
|
runHook preBuild
|
|
for file in $AOT_FILES
|
|
do
|
|
mono --aot $file
|
|
done
|
|
runHook postBuild
|
|
'';
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
mkdir -p $out/{bin,opt/mission-planner}
|
|
install -m 444 -D mpdesktop150.png $out/share/icons/mission-planner.png
|
|
cp -r ${desktopItem}/share/applications $out/share/
|
|
mv * $out/opt/mission-planner
|
|
makeWrapper ${mono6}/bin/mono $out/bin/mission-planner \
|
|
--add-flags $out/opt/mission-planner/MissionPlanner.exe
|
|
runHook postInstall
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "An ArduPilot ground station";
|
|
longDescription = ''
|
|
Full-featured ground station application for the ArduPilot open source
|
|
autopilot project. Lets you both flash, configure and control ArduPilot
|
|
Plane, Copter and Rover targets.
|
|
'';
|
|
homepage = "https://ardupilot.org/planner/";
|
|
license = licenses.gpl3Plus;
|
|
maintainers = with maintainers; [ wucke13 ];
|
|
platforms = platforms.all;
|
|
};
|
|
}
|