4a7f99d55d
Part of: https://github.com/NixOS/nixpkgs/issues/108938 meta = with stdenv.lib; is a widely used pattern. We want to slowly remove the `stdenv.lib` indirection and encourage people to use `lib` directly. Thus let’s start with the meta field. This used a rewriting script to mostly automatically replace all occurances of this pattern, and add the `lib` argument to the package header if it doesn’t exist yet. The script in its current form is available at https://cs.tvl.fyi/depot@2f807d7f141068d2d60676a89213eaa5353ca6e0/-/blob/users/Profpatsch/nixpkgs-rewriter/default.nix
47 lines
1.5 KiB
Nix
47 lines
1.5 KiB
Nix
{ stdenv, fetchurl, sane-backends, qtbase, qtsvg, nss, autoPatchelfHook, lib, wrapQtAppsHook }:
|
|
|
|
stdenv.mkDerivation rec {
|
|
pname = "masterpdfeditor";
|
|
version = "5.6.09";
|
|
|
|
src = fetchurl {
|
|
url = "https://code-industry.net/public/master-pdf-editor-${version}-qt5.amd64.tar.gz";
|
|
sha256 = "0v9j6fwr0xl03kr77vf4wdb06zlplmn4mr3jyzxhvs8a77scmfzb";
|
|
};
|
|
|
|
nativeBuildInputs = [ autoPatchelfHook wrapQtAppsHook ];
|
|
|
|
buildInputs = [ nss qtbase qtsvg sane-backends stdenv.cc.cc ];
|
|
|
|
dontStrip = true;
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
p=$out/opt/masterpdfeditor
|
|
mkdir -p $out/bin
|
|
|
|
substituteInPlace masterpdfeditor5.desktop \
|
|
--replace 'Exec=/opt/master-pdf-editor-5' "Exec=$out/bin" \
|
|
--replace 'Path=/opt/master-pdf-editor-5' "Path=$out/bin" \
|
|
--replace 'Icon=/opt/master-pdf-editor-5' "Icon=$out/share/pixmaps"
|
|
|
|
install -Dm644 -t $out/share/pixmaps masterpdfeditor5.png
|
|
install -Dm644 -t $out/share/applications masterpdfeditor5.desktop
|
|
install -Dm755 -t $p masterpdfeditor5
|
|
install -Dm644 license.txt $out/share/$name/LICENSE
|
|
ln -s $p/masterpdfeditor5 $out/bin/masterpdfeditor5
|
|
cp -v -r stamps templates lang fonts $p
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Master PDF Editor";
|
|
homepage = "https://code-industry.net/free-pdf-editor/";
|
|
license = licenses.unfreeRedistributable;
|
|
platforms = with platforms; [ "x86_64-linux" ];
|
|
maintainers = with maintainers; [ cmcdragonkai flokli ];
|
|
};
|
|
}
|