2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
99 lines
2.6 KiB
Nix
99 lines
2.6 KiB
Nix
{ lib, pkgs, config, ... }:
|
|
with lib;
|
|
let cfg = config.services.owncast;
|
|
in {
|
|
|
|
options.services.owncast = {
|
|
|
|
enable = mkEnableOption "owncast";
|
|
|
|
dataDir = mkOption {
|
|
type = types.str;
|
|
default = "/var/lib/owncast";
|
|
description = lib.mdDoc ''
|
|
The directory where owncast stores its data files. If left as the default value this directory will automatically be created before the owncast server starts, otherwise the sysadmin is responsible for ensuring the directory exists with appropriate ownership and permissions.
|
|
'';
|
|
};
|
|
|
|
openFirewall = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = lib.mdDoc ''
|
|
Open the appropriate ports in the firewall for owncast.
|
|
'';
|
|
};
|
|
|
|
user = mkOption {
|
|
type = types.str;
|
|
default = "owncast";
|
|
description = lib.mdDoc "User account under which owncast runs.";
|
|
};
|
|
|
|
group = mkOption {
|
|
type = types.str;
|
|
default = "owncast";
|
|
description = lib.mdDoc "Group under which owncast runs.";
|
|
};
|
|
|
|
listen = mkOption {
|
|
type = types.str;
|
|
default = "127.0.0.1";
|
|
example = "0.0.0.0";
|
|
description = lib.mdDoc "The IP address to bind the owncast web server to.";
|
|
};
|
|
|
|
port = mkOption {
|
|
type = types.port;
|
|
default = 8080;
|
|
description = lib.mdDoc ''
|
|
TCP port where owncast web-gui listens.
|
|
'';
|
|
};
|
|
|
|
rtmp-port = mkOption {
|
|
type = types.port;
|
|
default = 1935;
|
|
description = lib.mdDoc ''
|
|
TCP port where owncast rtmp service listens.
|
|
'';
|
|
};
|
|
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
|
|
systemd.services.owncast = {
|
|
description = "A self-hosted live video and web chat server";
|
|
wantedBy = [ "multi-user.target" ];
|
|
|
|
serviceConfig = mkMerge [
|
|
{
|
|
User = cfg.user;
|
|
Group = cfg.group;
|
|
WorkingDirectory = cfg.dataDir;
|
|
ExecStart = "${pkgs.owncast}/bin/owncast -webserverport ${toString cfg.port} -rtmpport ${toString cfg.rtmp-port} -webserverip ${cfg.listen}";
|
|
Restart = "on-failure";
|
|
}
|
|
(mkIf (cfg.dataDir == "/var/lib/owncast") {
|
|
StateDirectory = "owncast";
|
|
})
|
|
];
|
|
};
|
|
|
|
users.users = mkIf (cfg.user == "owncast") {
|
|
owncast = {
|
|
isSystemUser = true;
|
|
group = cfg.group;
|
|
description = "owncast system user";
|
|
};
|
|
};
|
|
|
|
users.groups = mkIf (cfg.group == "owncast") { owncast = { }; };
|
|
|
|
networking.firewall =
|
|
mkIf cfg.openFirewall { allowedTCPPorts = [ cfg.rtmp-port ] ++ optional (cfg.listen != "127.0.0.1") cfg.port; };
|
|
|
|
};
|
|
meta = { maintainers = with lib.maintainers; [ MayNiklas ]; };
|
|
}
|