38f37080c5
https://git.sr.ht/~c00w/nixpkgs/tree/sdimagebtrfs/item/nixos/lib/make-btrfs-fs.nix I made only one change which was to use `btrfs check` instead of `fsck.btrfs` because of this warning ``` btrfs-fs.img> ++ fsck.btrfs /nix/store/6d46rc768c140asy6rjpc5rk568r36zq-btrfs-fs.img btrfs-fs.img> If you wish to check the consistency of a BTRFS filesystem or btrfs-fs.img> repair a damaged filesystem, see btrfs(8) subcommand 'check'. ``` Co-authored-by: Colin L Rice <colin@daedrum.net>
66 lines
1.8 KiB
Nix
66 lines
1.8 KiB
Nix
# Builds an btrfs image containing a populated /nix/store with the closure
|
|
# of store paths passed in the storePaths parameter, in addition to the
|
|
# contents of a directory that can be populated with commands. The
|
|
# generated image is sized to only fit its contents, with the expectation
|
|
# that a script resizes the filesystem at boot time.
|
|
{ pkgs
|
|
, lib
|
|
# List of derivations to be included
|
|
, storePaths
|
|
# Whether or not to compress the resulting image with zstd
|
|
, compressImage ? false, zstd
|
|
# Shell commands to populate the ./files directory.
|
|
# All files in that directory are copied to the root of the FS.
|
|
, populateImageCommands ? ""
|
|
, volumeLabel
|
|
, uuid ? "44444444-4444-4444-8888-888888888888"
|
|
, btrfs-progs
|
|
}:
|
|
|
|
let
|
|
sdClosureInfo = pkgs.buildPackages.closureInfo { rootPaths = storePaths; };
|
|
in
|
|
pkgs.stdenv.mkDerivation {
|
|
name = "btrfs-fs.img${lib.optionalString compressImage ".zst"}";
|
|
|
|
nativeBuildInputs = [ btrfs-progs ] ++ lib.optional compressImage zstd;
|
|
|
|
buildCommand =
|
|
''
|
|
${if compressImage then "img=temp.img" else "img=$out"}
|
|
|
|
set -x
|
|
(
|
|
mkdir -p ./files
|
|
${populateImageCommands}
|
|
)
|
|
|
|
mkdir -p ./rootImage/nix/store
|
|
|
|
xargs -I % cp -a --reflink=auto % -t ./rootImage/nix/store/ < ${sdClosureInfo}/store-paths
|
|
(
|
|
GLOBIGNORE=".:.."
|
|
shopt -u dotglob
|
|
|
|
for f in ./files/*; do
|
|
cp -a --reflink=auto -t ./rootImage/ "$f"
|
|
done
|
|
)
|
|
|
|
cp ${sdClosureInfo}/registration ./rootImage/nix-path-registration
|
|
|
|
touch $img
|
|
mkfs.btrfs -L ${volumeLabel} -U ${uuid} -r ./rootImage --shrink $img
|
|
|
|
if ! btrfs check $img; then
|
|
echo "--- 'btrfs check' failed for BTRFS image ---"
|
|
return 1
|
|
fi
|
|
|
|
if [ ${builtins.toString compressImage} ]; then
|
|
echo "Compressing image"
|
|
zstd -v --no-progress ./$img -o $out
|
|
fi
|
|
'';
|
|
}
|