9bb3fccb5b
continuation of #109595 pkgconfig was aliased in 2018, however, it remained in all-packages.nix due to its wide usage. This cleans up the remaining references to pkgs.pkgsconfig and moves the entry to aliases.nix. python3Packages.pkgconfig remained unchanged because it's the canonical name of the upstream package on pypi.
56 lines
1.7 KiB
Nix
56 lines
1.7 KiB
Nix
{ lib, stdenv, fetchurl, pkg-config, pruneLibtoolFiles, flex, bison
|
|
, libmnl, libnetfilter_conntrack, libnfnetlink, libnftnl, libpcap
|
|
, nftablesCompat ? false
|
|
}:
|
|
|
|
with lib;
|
|
|
|
stdenv.mkDerivation rec {
|
|
version = "1.8.6";
|
|
pname = "iptables";
|
|
|
|
src = fetchurl {
|
|
url = "https://www.netfilter.org/projects/${pname}/files/${pname}-${version}.tar.bz2";
|
|
sha256 = "0rvp0k8a72h2snrdx48cfn75bfa0ycrd2xl3kjysbymq7q6gxx50";
|
|
};
|
|
|
|
nativeBuildInputs = [ pkg-config pruneLibtoolFiles flex bison ];
|
|
|
|
buildInputs = [ libmnl libnetfilter_conntrack libnfnetlink libnftnl libpcap ];
|
|
|
|
preConfigure = ''
|
|
export NIX_LDFLAGS="$NIX_LDFLAGS -lmnl -lnftnl"
|
|
'';
|
|
|
|
configureFlags = [
|
|
"--enable-bpf-compiler"
|
|
"--enable-devel"
|
|
"--enable-libipq"
|
|
"--enable-nfsynproxy"
|
|
"--enable-shared"
|
|
] ++ optional (!nftablesCompat) "--disable-nftables";
|
|
|
|
outputs = [ "out" "dev" ];
|
|
|
|
postInstall = optional nftablesCompat ''
|
|
rm $out/sbin/{iptables,iptables-restore,iptables-save,ip6tables,ip6tables-restore,ip6tables-save}
|
|
ln -sv xtables-nft-multi $out/bin/iptables
|
|
ln -sv xtables-nft-multi $out/bin/iptables-restore
|
|
ln -sv xtables-nft-multi $out/bin/iptables-save
|
|
ln -sv xtables-nft-multi $out/bin/ip6tables
|
|
ln -sv xtables-nft-multi $out/bin/ip6tables-restore
|
|
ln -sv xtables-nft-multi $out/bin/ip6tables-save
|
|
'';
|
|
|
|
meta = {
|
|
description = "A program to configure the Linux IP packet filtering ruleset";
|
|
homepage = "https://www.netfilter.org/projects/iptables/index.html";
|
|
platforms = platforms.linux;
|
|
maintainers = with maintainers; [ fpletz ];
|
|
license = licenses.gpl2;
|
|
downloadPage = "https://www.netfilter.org/projects/iptables/files/";
|
|
updateWalker = true;
|
|
inherit version;
|
|
};
|
|
}
|