2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
105 lines
2.9 KiB
Nix
105 lines
2.9 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.services.errbot;
|
|
pluginEnv = plugins: pkgs.buildEnv {
|
|
name = "errbot-plugins";
|
|
paths = plugins;
|
|
};
|
|
mkConfigDir = instanceCfg: dataDir: pkgs.writeTextDir "config.py" ''
|
|
import logging
|
|
BACKEND = '${instanceCfg.backend}'
|
|
BOT_DATA_DIR = '${dataDir}'
|
|
BOT_EXTRA_PLUGIN_DIR = '${pluginEnv instanceCfg.plugins}'
|
|
|
|
BOT_LOG_LEVEL = logging.${instanceCfg.logLevel}
|
|
BOT_LOG_FILE = False
|
|
|
|
BOT_ADMINS = (${concatMapStringsSep "," (name: "'${name}'") instanceCfg.admins})
|
|
|
|
BOT_IDENTITY = ${builtins.toJSON instanceCfg.identity}
|
|
|
|
${instanceCfg.extraConfig}
|
|
'';
|
|
in {
|
|
options = {
|
|
services.errbot.instances = mkOption {
|
|
default = {};
|
|
description = lib.mdDoc "Errbot instance configs";
|
|
type = types.attrsOf (types.submodule {
|
|
options = {
|
|
dataDir = mkOption {
|
|
type = types.nullOr types.path;
|
|
default = null;
|
|
description = lib.mdDoc "Data directory for errbot instance.";
|
|
};
|
|
|
|
plugins = mkOption {
|
|
type = types.listOf types.package;
|
|
default = [];
|
|
description = lib.mdDoc "List of errbot plugin derivations.";
|
|
};
|
|
|
|
logLevel = mkOption {
|
|
type = types.str;
|
|
default = "INFO";
|
|
description = lib.mdDoc "Errbot log level";
|
|
};
|
|
|
|
admins = mkOption {
|
|
type = types.listOf types.str;
|
|
default = [];
|
|
description = lib.mdDoc "List of identifiers of errbot admins.";
|
|
};
|
|
|
|
backend = mkOption {
|
|
type = types.str;
|
|
default = "XMPP";
|
|
description = lib.mdDoc "Errbot backend name.";
|
|
};
|
|
|
|
identity = mkOption {
|
|
type = types.attrs;
|
|
description = lib.mdDoc "Errbot identity configuration";
|
|
};
|
|
|
|
extraConfig = mkOption {
|
|
type = types.lines;
|
|
default = "";
|
|
description = lib.mdDoc "String to be appended to the config verbatim";
|
|
};
|
|
};
|
|
});
|
|
};
|
|
};
|
|
|
|
config = mkIf (cfg.instances != {}) {
|
|
users.users.errbot = {
|
|
group = "errbot";
|
|
isSystemUser = true;
|
|
};
|
|
users.groups.errbot = {};
|
|
|
|
systemd.services = mapAttrs' (name: instanceCfg: nameValuePair "errbot-${name}" (
|
|
let
|
|
dataDir = if instanceCfg.dataDir != null then instanceCfg.dataDir else
|
|
"/var/lib/errbot/${name}";
|
|
in {
|
|
after = [ "network-online.target" ];
|
|
wantedBy = [ "multi-user.target" ];
|
|
preStart = ''
|
|
mkdir -p ${dataDir}
|
|
chown -R errbot:errbot ${dataDir}
|
|
'';
|
|
serviceConfig = {
|
|
User = "errbot";
|
|
Restart = "on-failure";
|
|
ExecStart = "${pkgs.errbot}/bin/errbot -c ${mkConfigDir instanceCfg dataDir}/config.py";
|
|
PermissionsStartOnly = true;
|
|
};
|
|
})) cfg.instances;
|
|
};
|
|
}
|