2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
151 lines
3.7 KiB
Nix
151 lines
3.7 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
|
|
cfg = config.services.dspam;
|
|
|
|
dspam = pkgs.dspam;
|
|
|
|
defaultSock = "/run/dspam/dspam.sock";
|
|
|
|
cfgfile = pkgs.writeText "dspam.conf" ''
|
|
Home /var/lib/dspam
|
|
StorageDriver ${dspam}/lib/dspam/lib${cfg.storageDriver}_drv.so
|
|
|
|
Trust root
|
|
Trust ${cfg.user}
|
|
SystemLog on
|
|
UserLog on
|
|
|
|
${optionalString (cfg.domainSocket != null) ''
|
|
ServerDomainSocketPath "${cfg.domainSocket}"
|
|
ClientHost "${cfg.domainSocket}"
|
|
''}
|
|
|
|
${cfg.extraConfig}
|
|
'';
|
|
|
|
in {
|
|
|
|
###### interface
|
|
|
|
options = {
|
|
|
|
services.dspam = {
|
|
|
|
enable = mkOption {
|
|
type = types.bool;
|
|
default = false;
|
|
description = lib.mdDoc "Whether to enable the dspam spam filter.";
|
|
};
|
|
|
|
user = mkOption {
|
|
type = types.str;
|
|
default = "dspam";
|
|
description = lib.mdDoc "User for the dspam daemon.";
|
|
};
|
|
|
|
group = mkOption {
|
|
type = types.str;
|
|
default = "dspam";
|
|
description = lib.mdDoc "Group for the dspam daemon.";
|
|
};
|
|
|
|
storageDriver = mkOption {
|
|
type = types.str;
|
|
default = "hash";
|
|
description = lib.mdDoc "Storage driver backend to use for dspam.";
|
|
};
|
|
|
|
domainSocket = mkOption {
|
|
type = types.nullOr types.path;
|
|
default = defaultSock;
|
|
description = lib.mdDoc "Path to local domain socket which is used for communication with the daemon. Set to null to disable UNIX socket.";
|
|
};
|
|
|
|
extraConfig = mkOption {
|
|
type = types.lines;
|
|
default = "";
|
|
description = lib.mdDoc "Additional dspam configuration.";
|
|
};
|
|
|
|
maintenanceInterval = mkOption {
|
|
type = types.nullOr types.str;
|
|
default = null;
|
|
description = lib.mdDoc "If set, maintenance script will be run at specified (in systemd.timer format) interval";
|
|
};
|
|
|
|
};
|
|
|
|
};
|
|
|
|
|
|
###### implementation
|
|
|
|
config = mkIf cfg.enable (mkMerge [
|
|
{
|
|
users.users = optionalAttrs (cfg.user == "dspam") {
|
|
dspam = {
|
|
group = cfg.group;
|
|
uid = config.ids.uids.dspam;
|
|
};
|
|
};
|
|
|
|
users.groups = optionalAttrs (cfg.group == "dspam") {
|
|
dspam.gid = config.ids.gids.dspam;
|
|
};
|
|
|
|
environment.systemPackages = [ dspam ];
|
|
|
|
environment.etc."dspam/dspam.conf".source = cfgfile;
|
|
|
|
systemd.services.dspam = {
|
|
description = "dspam spam filtering daemon";
|
|
wantedBy = [ "multi-user.target" ];
|
|
after = [ "postgresql.service" ];
|
|
restartTriggers = [ cfgfile ];
|
|
|
|
serviceConfig = {
|
|
ExecStart = "${dspam}/bin/dspam --daemon --nofork";
|
|
User = cfg.user;
|
|
Group = cfg.group;
|
|
RuntimeDirectory = optional (cfg.domainSocket == defaultSock) "dspam";
|
|
RuntimeDirectoryMode = optional (cfg.domainSocket == defaultSock) "0750";
|
|
StateDirectory = "dspam";
|
|
StateDirectoryMode = "0750";
|
|
LogsDirectory = "dspam";
|
|
LogsDirectoryMode = "0750";
|
|
# DSPAM segfaults on just about every error
|
|
Restart = "on-abort";
|
|
RestartSec = "1s";
|
|
};
|
|
};
|
|
}
|
|
|
|
(mkIf (cfg.maintenanceInterval != null) {
|
|
systemd.timers.dspam-maintenance = {
|
|
description = "Timer for dspam maintenance script";
|
|
wantedBy = [ "timers.target" ];
|
|
timerConfig = {
|
|
OnCalendar = cfg.maintenanceInterval;
|
|
Unit = "dspam-maintenance.service";
|
|
};
|
|
};
|
|
|
|
systemd.services.dspam-maintenance = {
|
|
description = "dspam maintenance script";
|
|
restartTriggers = [ cfgfile ];
|
|
|
|
serviceConfig = {
|
|
ExecStart = "${dspam}/bin/dspam_maintenance --verbose";
|
|
Type = "oneshot";
|
|
User = cfg.user;
|
|
Group = cfg.group;
|
|
};
|
|
};
|
|
})
|
|
]);
|
|
}
|