6afb255d97
these changes were generated with nixq 0.0.2, by running nixq ">> lib.mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> Inherit >> mdDoc[remove]" --batchmode nixos/**.nix two mentions of the mdDoc function remain in nixos/, both of which are inside of comments. Since lib.mdDoc is already defined as just id, this commit is a no-op as far as Nix (and the built manual) is concerned.
73 lines
1.8 KiB
Nix
73 lines
1.8 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.services.ankisyncd;
|
|
|
|
name = "ankisyncd";
|
|
|
|
stateDir = "/var/lib/${name}";
|
|
|
|
toml = pkgs.formats.toml {};
|
|
|
|
configFile = toml.generate "ankisyncd.conf" {
|
|
listen = {
|
|
host = cfg.host;
|
|
port = cfg.port;
|
|
};
|
|
paths.root_dir = stateDir;
|
|
# encryption.ssl_enable / cert_file / key_file
|
|
};
|
|
in
|
|
{
|
|
options.services.ankisyncd = {
|
|
enable = mkEnableOption "ankisyncd, a standalone unofficial anky sync server";
|
|
|
|
package = mkPackageOption pkgs "ankisyncd" { };
|
|
|
|
host = mkOption {
|
|
type = types.str;
|
|
default = "localhost";
|
|
description = "ankisyncd host";
|
|
};
|
|
|
|
port = mkOption {
|
|
type = types.port;
|
|
default = 27701;
|
|
description = "ankisyncd port";
|
|
};
|
|
|
|
openFirewall = mkOption {
|
|
default = false;
|
|
type = types.bool;
|
|
description = "Whether to open the firewall for the specified port.";
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
warnings = [
|
|
''
|
|
`services.ankisyncd` has been replaced by `services.anki-sync-server` and will be removed after
|
|
24.05 because anki-sync-server(-rs and python) are not maintained.
|
|
''
|
|
];
|
|
networking.firewall.allowedTCPPorts = mkIf cfg.openFirewall [ cfg.port ];
|
|
|
|
systemd.services.ankisyncd = {
|
|
description = "ankisyncd - Anki sync server";
|
|
after = [ "network.target" ];
|
|
wantedBy = [ "multi-user.target" ];
|
|
path = [ cfg.package ];
|
|
|
|
serviceConfig = {
|
|
Type = "simple";
|
|
DynamicUser = true;
|
|
StateDirectory = name;
|
|
ExecStart = "${cfg.package}/bin/ankisyncd --config ${configFile}";
|
|
Restart = "always";
|
|
};
|
|
};
|
|
};
|
|
}
|