6afb255d97
these changes were generated with nixq 0.0.2, by running nixq ">> lib.mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> Inherit >> mdDoc[remove]" --batchmode nixos/**.nix two mentions of the mdDoc function remain in nixos/, both of which are inside of comments. Since lib.mdDoc is already defined as just id, this commit is a no-op as far as Nix (and the built manual) is concerned.
68 lines
1.3 KiB
Nix
68 lines
1.3 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.services.dwm-status;
|
|
|
|
order = concatMapStringsSep "," (feature: ''"${feature}"'') cfg.order;
|
|
|
|
configFile = pkgs.writeText "dwm-status.toml" ''
|
|
order = [${order}]
|
|
|
|
${cfg.extraConfig}
|
|
'';
|
|
in
|
|
|
|
{
|
|
|
|
###### interface
|
|
|
|
options = {
|
|
|
|
services.dwm-status = {
|
|
|
|
enable = mkEnableOption "dwm-status user service";
|
|
|
|
package = mkPackageOption pkgs "dwm-status" {
|
|
example = "dwm-status.override { enableAlsaUtils = false; }";
|
|
};
|
|
|
|
order = mkOption {
|
|
type = types.listOf (types.enum [ "audio" "backlight" "battery" "cpu_load" "network" "time" ]);
|
|
description = ''
|
|
List of enabled features in order.
|
|
'';
|
|
};
|
|
|
|
extraConfig = mkOption {
|
|
type = types.lines;
|
|
default = "";
|
|
description = ''
|
|
Extra config in TOML format.
|
|
'';
|
|
};
|
|
|
|
};
|
|
|
|
};
|
|
|
|
|
|
###### implementation
|
|
|
|
config = mkIf cfg.enable {
|
|
|
|
services.upower.enable = elem "battery" cfg.order;
|
|
|
|
systemd.user.services.dwm-status = {
|
|
description = "Highly performant and configurable DWM status service";
|
|
wantedBy = [ "graphical-session.target" ];
|
|
partOf = [ "graphical-session.target" ];
|
|
|
|
serviceConfig.ExecStart = "${cfg.package}/bin/dwm-status ${configFile}";
|
|
};
|
|
|
|
};
|
|
|
|
}
|