6afb255d97
these changes were generated with nixq 0.0.2, by running nixq ">> lib.mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> Inherit >> mdDoc[remove]" --batchmode nixos/**.nix two mentions of the mdDoc function remain in nixos/, both of which are inside of comments. Since lib.mdDoc is already defined as just id, this commit is a no-op as far as Nix (and the built manual) is concerned.
64 lines
1.5 KiB
Nix
64 lines
1.5 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
with lib;
|
|
|
|
let
|
|
cfg = config.services.weechat;
|
|
in
|
|
|
|
{
|
|
options.services.weechat = {
|
|
enable = mkEnableOption "weechat";
|
|
root = mkOption {
|
|
description = "Weechat state directory.";
|
|
type = types.str;
|
|
default = "/var/lib/weechat";
|
|
};
|
|
sessionName = mkOption {
|
|
description = "Name of the `screen` session for weechat.";
|
|
default = "weechat-screen";
|
|
type = types.str;
|
|
};
|
|
binary = mkOption {
|
|
type = types.path;
|
|
description = "Binary to execute.";
|
|
default = "${pkgs.weechat}/bin/weechat";
|
|
defaultText = literalExpression ''"''${pkgs.weechat}/bin/weechat"'';
|
|
example = literalExpression ''"''${pkgs.weechat}/bin/weechat-headless"'';
|
|
};
|
|
};
|
|
|
|
config = mkIf cfg.enable {
|
|
users = {
|
|
groups.weechat = {};
|
|
users.weechat = {
|
|
createHome = true;
|
|
group = "weechat";
|
|
home = cfg.root;
|
|
isSystemUser = true;
|
|
};
|
|
};
|
|
|
|
systemd.services.weechat = {
|
|
environment.WEECHAT_HOME = cfg.root;
|
|
serviceConfig = {
|
|
User = "weechat";
|
|
Group = "weechat";
|
|
RemainAfterExit = "yes";
|
|
};
|
|
script = "exec ${config.security.wrapperDir}/screen -Dm -S ${cfg.sessionName} ${cfg.binary}";
|
|
wantedBy = [ "multi-user.target" ];
|
|
wants = [ "network.target" ];
|
|
};
|
|
|
|
security.wrappers.screen =
|
|
{ setuid = true;
|
|
owner = "root";
|
|
group = "root";
|
|
source = "${pkgs.screen}/bin/screen";
|
|
};
|
|
};
|
|
|
|
meta.doc = ./weechat.md;
|
|
}
|