6afb255d97
these changes were generated with nixq 0.0.2, by running nixq ">> lib.mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> Inherit >> mdDoc[remove]" --batchmode nixos/**.nix two mentions of the mdDoc function remain in nixos/, both of which are inside of comments. Since lib.mdDoc is already defined as just id, this commit is a no-op as far as Nix (and the built manual) is concerned.
39 lines
1.0 KiB
Nix
39 lines
1.0 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
let
|
|
cfg = config.services.zram-generator;
|
|
settingsFormat = pkgs.formats.ini { };
|
|
in
|
|
{
|
|
meta = {
|
|
maintainers = with lib.maintainers; [ nickcao ];
|
|
};
|
|
|
|
options.services.zram-generator = {
|
|
enable = lib.mkEnableOption "Systemd unit generator for zram devices";
|
|
|
|
package = lib.mkPackageOption pkgs "zram-generator" { };
|
|
|
|
settings = lib.mkOption {
|
|
type = lib.types.submodule {
|
|
freeformType = settingsFormat.type;
|
|
};
|
|
default = { };
|
|
description = ''
|
|
Configuration for zram-generator,
|
|
see https://github.com/systemd/zram-generator for documentation.
|
|
'';
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf cfg.enable {
|
|
system.requiredKernelConfig = with config.lib.kernelConfig; [
|
|
(isEnabled "ZRAM")
|
|
];
|
|
|
|
systemd.packages = [ cfg.package ];
|
|
systemd.services."systemd-zram-setup@".path = [ pkgs.util-linux ]; # for mkswap
|
|
|
|
environment.etc."systemd/zram-generator.conf".source = settingsFormat.generate "zram-generator.conf" cfg.settings;
|
|
};
|
|
}
|