6afb255d97
these changes were generated with nixq 0.0.2, by running nixq ">> lib.mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> mdDoc[remove] Argument[keep]" --batchmode nixos/**.nix nixq ">> Inherit >> mdDoc[remove]" --batchmode nixos/**.nix two mentions of the mdDoc function remain in nixos/, both of which are inside of comments. Since lib.mdDoc is already defined as just id, this commit is a no-op as far as Nix (and the built manual) is concerned.
49 lines
1.1 KiB
Nix
49 lines
1.1 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
|
|
let
|
|
cfg = config.programs.nano;
|
|
in
|
|
|
|
{
|
|
options = {
|
|
programs.nano = {
|
|
enable = lib.mkEnableOption "nano, a small user-friendly console text editor" // {
|
|
default = true;
|
|
};
|
|
|
|
package = lib.mkPackageOption pkgs "nano" { };
|
|
|
|
nanorc = lib.mkOption {
|
|
type = lib.types.lines;
|
|
default = "";
|
|
description = ''
|
|
The system-wide nano configuration.
|
|
See {manpage}`nanorc(5)`.
|
|
'';
|
|
example = ''
|
|
set nowrap
|
|
set tabstospaces
|
|
set tabsize 2
|
|
'';
|
|
};
|
|
|
|
syntaxHighlight = lib.mkOption {
|
|
type = lib.types.bool;
|
|
default = true;
|
|
description = "Whether to enable syntax highlight for various languages.";
|
|
};
|
|
};
|
|
};
|
|
|
|
config = lib.mkIf cfg.enable {
|
|
environment = {
|
|
etc.nanorc.text = (lib.optionalString cfg.syntaxHighlight ''
|
|
# load syntax highlighting files
|
|
include "${cfg.package}/share/nano/*.nanorc"
|
|
include "${cfg.package}/share/nano/extra/*.nanorc"
|
|
'') + cfg.nanorc;
|
|
systemPackages = [ cfg.package ];
|
|
};
|
|
};
|
|
}
|