![Yarny0](/assets/img/avatar_default.png)
This commit changes from a precompiled bundle to a source file. Accordingly, the expression file is renamed to `default.nix` and the old attribute name is changed to `tvbrowser`, the old one being now a throw-message. The upstream build script tries to download the news plugin; so, we provide this and pass it as a parameter. Given that this is still a piece of a precompiled Java bytecode, along with a main readable source bundle, `meta.sourceProvenance` is updated accordingly.
84 lines
2.2 KiB
Nix
84 lines
2.2 KiB
Nix
{ lib
|
|
, fetchurl
|
|
, makeDesktopItem
|
|
, stdenv
|
|
, fetchzip
|
|
, ant
|
|
, jdk
|
|
, makeWrapper
|
|
}:
|
|
|
|
let
|
|
minimalJavaVersion = "11";
|
|
|
|
newsPlugin = fetchurl {
|
|
url = "https://www.tvbrowser.org/data/uploads/1372016422809_543/NewsPlugin.jar";
|
|
hash = "sha256-5XoypuMd2AFBE2SJ6EdECuvq6D81HLLuu9UoA9kcKAM=";
|
|
};
|
|
|
|
desktopItem = makeDesktopItem {
|
|
name = "tvbrowser";
|
|
exec = "tvbrowser";
|
|
icon = "tvbrowser";
|
|
comment = "Themeable and easy to use TV Guide";
|
|
desktopName = "TV-Browser";
|
|
genericName = "Electronic TV Program Guide";
|
|
categories = [ "AudioVideo" "TV" "Java" ];
|
|
startupNotify = true;
|
|
startupWMClass = "tvbrowser-TVBrowser";
|
|
};
|
|
|
|
in
|
|
assert lib.versionAtLeast jdk.version minimalJavaVersion;
|
|
stdenv.mkDerivation rec {
|
|
pname = "tvbrowser";
|
|
version = "4.2.7";
|
|
|
|
src = fetchzip {
|
|
url = "mirror://sourceforge/${pname}/TV-Browser%20Releases%20%28Java%20${minimalJavaVersion}%20and%20higher%29/${version}/${pname}_${version}_src.tar.gz";
|
|
hash = "sha256-dmNfI6T0MU7UtMH+C/2hiAeDwZlFCB4JofQViZezoqI=";
|
|
};
|
|
|
|
nativeBuildInputs = [ ant jdk makeWrapper ];
|
|
|
|
buildPhase = ''
|
|
runHook preBuild
|
|
|
|
ant runtime-linux -Dnewsplugin.url=file://${newsPlugin}
|
|
|
|
runHook postBuild
|
|
'';
|
|
|
|
installPhase = ''
|
|
runHook preInstall
|
|
|
|
mkdir -p $out/share/java/${pname}
|
|
cp -R runtime/tvbrowser_linux/* $out/share/java/${pname}
|
|
rm $out/share/java/${pname}/${pname}.sh
|
|
|
|
mkdir -p $out/share/applications
|
|
ln -s ${desktopItem}/share/applications/* $out/share/applications/
|
|
|
|
for i in 16 32 48 128; do
|
|
mkdir -p $out/share/icons/hicolor/''${i}x''${i}/apps
|
|
ln -s $out/share/java/${pname}/imgs/${pname}$i.png $out/share/icons/hicolor/''${i}x''${i}/apps/${pname}.png
|
|
done
|
|
|
|
mkdir -p $out/bin
|
|
makeWrapper ${jdk}/bin/java $out/bin/${pname} \
|
|
--add-flags "--module-path=lib:${pname}.jar -m ${pname}/tvbrowser.TVBrowser" \
|
|
--chdir "$out/share/java/${pname}"
|
|
|
|
runHook postInstall
|
|
'';
|
|
|
|
meta = with lib; {
|
|
description = "Electronic TV Program Guide";
|
|
homepage = "https://www.tvbrowser.org/";
|
|
sourceProvenance = with sourceTypes; [ binaryBytecode fromSource ];
|
|
license = licenses.gpl3;
|
|
platforms = platforms.linux;
|
|
maintainers = with maintainers; [ jfrankenau yarny ];
|
|
};
|
|
}
|