c03b74224a
Currently Erigon binary fails to start on some systems with: ``` > erigon --version Caught SIGILL in blst_cgo_init, consult <blst>/bindinds/go/README.md. ``` The reason for that are missing `CGO_CFLAGS` that can be seen here: https://github.com/ledgerwatch/erigon/blob/v2.53.2/Makefile#L26 For more information on this see this `bsc` issue: https://github.com/bnb-chain/bsc/issues/1521 Signed-off-by: Jakub Sokołowski <jakub@status.im>
46 lines
1.2 KiB
Nix
46 lines
1.2 KiB
Nix
{ lib, buildGoModule, fetchFromGitHub, nix-update-script }:
|
|
|
|
let
|
|
pname = "erigon";
|
|
version = "2.53.1";
|
|
in
|
|
buildGoModule {
|
|
inherit pname version;
|
|
|
|
src = fetchFromGitHub {
|
|
owner = "ledgerwatch";
|
|
repo = pname;
|
|
rev = "v${version}";
|
|
hash = "sha256-Gsrt/+6fhpwg3DzPtXPj9T9VPaMIaRcYBdWuFOotsbA=";
|
|
fetchSubmodules = true;
|
|
};
|
|
|
|
vendorHash = "sha256-zsLPqcLCZSnhlFWvNXZJwlfS+NsaTS07TmWd+x4ZPXA=";
|
|
proxyVendor = true;
|
|
|
|
# Build errors in mdbx when format hardening is enabled:
|
|
# cc1: error: '-Wformat-security' ignored without '-Wformat' [-Werror=format-security]
|
|
hardeningDisable = [ "format" ];
|
|
|
|
# Fix error: 'Caught SIGILL in blst_cgo_init'
|
|
# https://github.com/bnb-chain/bsc/issues/1521
|
|
CGO_CFLAGS = "-O -D__BLST_PORTABLE__";
|
|
CGO_CFLAGS_ALLOW = "-O -D__BLST_PORTABLE__";
|
|
|
|
subPackages = [
|
|
"cmd/erigon"
|
|
"cmd/evm"
|
|
"cmd/rpcdaemon"
|
|
"cmd/rlpdump"
|
|
];
|
|
|
|
passthru.updateScript = nix-update-script { };
|
|
|
|
meta = with lib; {
|
|
homepage = "https://github.com/ledgerwatch/erigon/";
|
|
description = "Ethereum node implementation focused on scalability and modularity";
|
|
license = with licenses; [ lgpl3Plus gpl3Plus ];
|
|
maintainers = with maintainers; [ d-xo happysalada ];
|
|
};
|
|
}
|