2e751c0772
the conversion procedure is simple: - find all things that look like options, ie calls to either `mkOption` or `lib.mkOption` that take an attrset. remember the attrset as the option - for all options, find a `description` attribute who's value is not a call to `mdDoc` or `lib.mdDoc` - textually convert the entire value of the attribute to MD with a few simple regexes (the set from mdize-module.sh) - if the change produced a change in the manual output, discard - if the change kept the manual unchanged, add some text to the description to make sure we've actually found an option. if the manual changes this time, keep the converted description this procedure converts 80% of nixos options to markdown. around 2000 options remain to be inspected, but most of those fail the "does not change the manual output check": currently the MD conversion process does not faithfully convert docbook tags like <code> and <package>, so any option using such tags will not be converted at all.
152 lines
4.6 KiB
Nix
152 lines
4.6 KiB
Nix
{ config, lib, pkgs, ... }:
|
|
with lib;
|
|
let
|
|
clamavUser = "clamav";
|
|
stateDir = "/var/lib/clamav";
|
|
runDir = "/run/clamav";
|
|
clamavGroup = clamavUser;
|
|
cfg = config.services.clamav;
|
|
pkg = pkgs.clamav;
|
|
|
|
toKeyValue = generators.toKeyValue {
|
|
mkKeyValue = generators.mkKeyValueDefault { } " ";
|
|
listsAsDuplicateKeys = true;
|
|
};
|
|
|
|
clamdConfigFile = pkgs.writeText "clamd.conf" (toKeyValue cfg.daemon.settings);
|
|
freshclamConfigFile = pkgs.writeText "freshclam.conf" (toKeyValue cfg.updater.settings);
|
|
in
|
|
{
|
|
imports = [
|
|
(mkRemovedOptionModule [ "services" "clamav" "updater" "config" ] "Use services.clamav.updater.settings instead.")
|
|
(mkRemovedOptionModule [ "services" "clamav" "updater" "extraConfig" ] "Use services.clamav.updater.settings instead.")
|
|
(mkRemovedOptionModule [ "services" "clamav" "daemon" "extraConfig" ] "Use services.clamav.daemon.settings instead.")
|
|
];
|
|
|
|
options = {
|
|
services.clamav = {
|
|
daemon = {
|
|
enable = mkEnableOption "ClamAV clamd daemon";
|
|
|
|
settings = mkOption {
|
|
type = with types; attrsOf (oneOf [ bool int str (listOf str) ]);
|
|
default = { };
|
|
description = lib.mdDoc ''
|
|
ClamAV configuration. Refer to <https://linux.die.net/man/5/clamd.conf>,
|
|
for details on supported values.
|
|
'';
|
|
};
|
|
};
|
|
updater = {
|
|
enable = mkEnableOption "ClamAV freshclam updater";
|
|
|
|
frequency = mkOption {
|
|
type = types.int;
|
|
default = 12;
|
|
description = lib.mdDoc ''
|
|
Number of database checks per day.
|
|
'';
|
|
};
|
|
|
|
interval = mkOption {
|
|
type = types.str;
|
|
default = "hourly";
|
|
description = lib.mdDoc ''
|
|
How often freshclam is invoked. See systemd.time(7) for more
|
|
information about the format.
|
|
'';
|
|
};
|
|
|
|
settings = mkOption {
|
|
type = with types; attrsOf (oneOf [ bool int str (listOf str) ]);
|
|
default = { };
|
|
description = lib.mdDoc ''
|
|
freshclam configuration. Refer to <https://linux.die.net/man/5/freshclam.conf>,
|
|
for details on supported values.
|
|
'';
|
|
};
|
|
};
|
|
};
|
|
};
|
|
|
|
config = mkIf (cfg.updater.enable || cfg.daemon.enable) {
|
|
environment.systemPackages = [ pkg ];
|
|
|
|
users.users.${clamavUser} = {
|
|
uid = config.ids.uids.clamav;
|
|
group = clamavGroup;
|
|
description = "ClamAV daemon user";
|
|
home = stateDir;
|
|
};
|
|
|
|
users.groups.${clamavGroup} =
|
|
{ gid = config.ids.gids.clamav; };
|
|
|
|
services.clamav.daemon.settings = {
|
|
DatabaseDirectory = stateDir;
|
|
LocalSocket = "${runDir}/clamd.ctl";
|
|
PidFile = "${runDir}/clamd.pid";
|
|
TemporaryDirectory = "/tmp";
|
|
User = "clamav";
|
|
Foreground = true;
|
|
};
|
|
|
|
services.clamav.updater.settings = {
|
|
DatabaseDirectory = stateDir;
|
|
Foreground = true;
|
|
Checks = cfg.updater.frequency;
|
|
DatabaseMirror = [ "database.clamav.net" ];
|
|
};
|
|
|
|
environment.etc."clamav/freshclam.conf".source = freshclamConfigFile;
|
|
environment.etc."clamav/clamd.conf".source = clamdConfigFile;
|
|
|
|
systemd.services.clamav-daemon = mkIf cfg.daemon.enable {
|
|
description = "ClamAV daemon (clamd)";
|
|
after = optional cfg.updater.enable "clamav-freshclam.service";
|
|
wantedBy = [ "multi-user.target" ];
|
|
restartTriggers = [ clamdConfigFile ];
|
|
|
|
preStart = ''
|
|
mkdir -m 0755 -p ${runDir}
|
|
chown ${clamavUser}:${clamavGroup} ${runDir}
|
|
'';
|
|
|
|
serviceConfig = {
|
|
ExecStart = "${pkg}/bin/clamd";
|
|
ExecReload = "${pkgs.coreutils}/bin/kill -USR2 $MAINPID";
|
|
PrivateTmp = "yes";
|
|
PrivateDevices = "yes";
|
|
PrivateNetwork = "yes";
|
|
};
|
|
};
|
|
|
|
systemd.timers.clamav-freshclam = mkIf cfg.updater.enable {
|
|
description = "Timer for ClamAV virus database updater (freshclam)";
|
|
wantedBy = [ "timers.target" ];
|
|
timerConfig = {
|
|
OnCalendar = cfg.updater.interval;
|
|
Unit = "clamav-freshclam.service";
|
|
};
|
|
};
|
|
|
|
systemd.services.clamav-freshclam = mkIf cfg.updater.enable {
|
|
description = "ClamAV virus database updater (freshclam)";
|
|
restartTriggers = [ freshclamConfigFile ];
|
|
after = [ "network-online.target" ];
|
|
preStart = ''
|
|
mkdir -m 0755 -p ${stateDir}
|
|
chown ${clamavUser}:${clamavGroup} ${stateDir}
|
|
'';
|
|
|
|
serviceConfig = {
|
|
Type = "oneshot";
|
|
ExecStart = "${pkg}/bin/freshclam";
|
|
SuccessExitStatus = "1"; # if databases are up to date
|
|
PrivateTmp = "yes";
|
|
PrivateDevices = "yes";
|
|
};
|
|
};
|
|
};
|
|
}
|