nixpkgs/pkgs/shells/bash/default.nix
Rob Vermaas e8601a4227 explicitly disable readline support for bash on darwin, hacky for now, to avoid massive rebuild
svn path=/nixpkgs/branches/stdenv-updates/; revision=19678
2010-01-26 16:04:53 +00:00

76 lines
2.3 KiB
Nix

{stdenv, fetchurl, readline ? null, interactive ? false, texinfo ? null, bison}:
assert interactive -> readline != null;
stdenv.mkDerivation (rec {
name = "bash-4.1";
src = fetchurl {
url = "mirror://gnu/bash/${name}.tar.gz";
sha256 = "1np1ggp1lv8idwfx3mcxl9rhadqdf4h3x4isa3dk8v9wm0j72qiz";
};
NIX_CFLAGS_COMPILE = ''
-DSYS_BASHRC="/etc/bashrc"
-DSYS_BASH_LOGOUT="/etc/bash_logout"
-DDEFAULT_PATH_VALUE="/no-such-path"
-DSTANDARD_UTILS_PATH="/no-such-path"
-DNON_INTERACTIVE_LOGIN_SHELLS
-DSSH_SOURCE_BASHRC
'';
patchFlags = "-p0";
patches =
let
patch = nr: sha256:
fetchurl {
url = "mirror://gnu/bash/bash-4.1-patches/bash41-${nr}";
inherit sha256;
};
in
import ./bash-patches.nix patch;
# Note: Bison is needed because the patches above modify parse.y.
buildNativeInputs = [bison];
buildInputs = stdenv.lib.optional (texinfo != null) texinfo
++ stdenv.lib.optional interactive readline;
configureFlags = "--with-installed-readline";
postInstall = ''
# Add an `sh' -> `bash' symlink.
ln -s bash "$out/bin/sh"
# Install the completion examples.
ensureDir "$out/etc"
cp -v "examples/complete/bash_completion" "$out/etc"
ensureDir "$out/etc/bash_completion.d"
cp -v "examples/complete/complete.gnu-longopt" "$out/etc/bash_completion.d"
'';
meta = {
homepage = http://www.gnu.org/software/bash/;
description =
"GNU Bourne-Again Shell, the de facto standard shell on Linux" +
(if interactive then " (for interactive use)" else "");
longDescription = ''
Bash is the shell, or command language interpreter, that will
appear in the GNU operating system. Bash is an sh-compatible
shell that incorporates useful features from the Korn shell
(ksh) and C shell (csh). It is intended to conform to the IEEE
POSIX P1003.2/ISO 9945.2 Shell and Tools standard. It offers
functional improvements over sh for both programming and
interactive use. In addition, most sh scripts can be run by
Bash without modification.
'';
license = "GPLv3+";
maintainers = [ stdenv.lib.maintainers.ludo ];
};
} // (if stdenv.isDarwin then { configureFlags = if interactive then "--with-installed-readline" else "--disable-readline"; } else {}) )