63746cac08
This PR refactor CUDA setup hooks, and in particular autoAddOpenGLRunpath and autoAddCudaCompatRunpathHook, that were using a lot of code in common (in fact, I introduced the latter by copy pasting most of the bash script of the former). This is not satisfying for maintenance, as a recent patch showed, because we need to duplicate changes to both hooks. This commit abstract the common part in a single shell script that applies a generic patch action to every elf file in the output. For autoAddOpenGLRunpath the action is just addOpenGLRunpath (now addDriverRunpath), and is few line function for autoAddCudaCompatRunpathHook. Doing so, we also takes the occasion to use the newer addDriverRunpath instead of the previous addOpenGLRunpath, and rename the CUDA hook to reflect that as well. Co-Authored-By: Connor Baker <connor.baker@tweag.io>
56 lines
1.2 KiB
Nix
56 lines
1.2 KiB
Nix
{ lib
|
|
, python
|
|
, buildPythonPackage
|
|
, autoPatchelfHook
|
|
, unzip
|
|
, cudaPackages
|
|
}:
|
|
|
|
let
|
|
pyVersion = "${lib.versions.major python.version}${lib.versions.minor python.version}";
|
|
in
|
|
buildPythonPackage rec {
|
|
pname = "tensorrt";
|
|
version = lib.optionalString (cudaPackages ? tensorrt) cudaPackages.tensorrt.version;
|
|
|
|
src = cudaPackages.tensorrt.src;
|
|
|
|
format = "wheel";
|
|
# We unpack the wheel ourselves because of the odd packaging.
|
|
dontUseWheelUnpack = true;
|
|
|
|
nativeBuildInputs = [
|
|
unzip
|
|
autoPatchelfHook
|
|
cudaPackages.autoAddDriverRunpath
|
|
];
|
|
|
|
preUnpack = ''
|
|
mkdir -p dist
|
|
tar --strip-components=2 -xf "$src" --directory=dist \
|
|
"TensorRT-${version}/python/tensorrt-${version}-cp${pyVersion}-none-linux_x86_64.whl"
|
|
'';
|
|
|
|
sourceRoot = ".";
|
|
|
|
buildInputs = [
|
|
cudaPackages.cudnn
|
|
cudaPackages.tensorrt
|
|
];
|
|
|
|
pythonImportsCheck = [
|
|
"tensorrt"
|
|
];
|
|
|
|
meta = with lib; {
|
|
description = "Python bindings for TensorRT, a high-performance deep learning interface";
|
|
homepage = "https://developer.nvidia.com/tensorrt";
|
|
license = licenses.unfree;
|
|
platforms = [ "x86_64-linux" ];
|
|
maintainers = with maintainers; [ aidalgol ];
|
|
broken =
|
|
!(cudaPackages ? tensorrt)
|
|
|| !(cudaPackages ? cudnn);
|
|
};
|
|
}
|