Files
wireplumber/lib/wp/meson.build
George Kiagiadakis a63f2bb99b lib/wp: merge both WpRemote & WpRemotePipewire in WpCore
In practice we always create a remote and connect to pipewire.
Any other scenario is invalid, therefore, it is not justified
to be confused with so many classes for such small functionality.
This simplifies a lot the modules code.

Also, this commit exposes the pw_core and pw_remote objects
out of WpCore. This is in practice useful when dealing with low-level
pw and spa factories, which are used in the monitors. Let's not
add API wrappers for everything... Bindings will never use this
functionality anyway, since it depends on low level pipewire C API.
2019-09-07 17:55:46 +03:00

68 lines
1.4 KiB
Meson

wp_lib_sources = [
'core.c',
'endpoint.c',
'error.c',
'factory.c',
'module.c',
'policy.c',
'properties.c',
'proxy.c',
'proxy-client.c',
'proxy-link.c',
'proxy-node.c',
'proxy-port.c',
]
wp_lib_headers = [
'core.h',
'endpoint.h',
'error.h',
'factory.h',
'module.h',
'policy.h',
'properties.h',
'proxy.h',
'proxy-client.h',
'proxy-node.h',
'proxy-port.h',
'proxy-link.h',
'wp.h',
]
install_headers(wp_lib_headers,
subdir : join_paths('wireplumber-' + wireplumber_api_version, 'wp')
)
enums = gnome.mkenums_simple('wpenums', sources: wp_lib_headers)
wp_lib = library('wireplumber-' + wireplumber_api_version,
wp_lib_sources, enums,
c_args : [
'-D_GNU_SOURCE',
'-DG_LOG_USE_STRUCTURED',
'-DG_LOG_DOMAIN="libwireplumber"',
'-DWIREPLUMBER_DEFAULT_MODULE_DIR="@0@"'.format(wireplumber_module_dir),
],
install: true,
include_directories: wp_lib_include_dir,
dependencies : [gobject_dep, gmodule_dep, gio_dep, pipewire_dep],
soversion: wireplumber_so_version,
version: meson.project_version(),
)
if get_option('introspection')
gnome.generate_gir(wp_lib,
namespace: 'Wp',
nsversion: wireplumber_api_version,
sources: [wp_lib_sources, wp_lib_headers, enums],
includes: ['GLib-2.0', 'GObject-2.0', 'Gio-2.0'],
install: true,
)
endif
wp_dep = declare_dependency(
link_with: wp_lib,
include_directories: wp_lib_include_dir,
dependencies: [gobject_dep]
)