217 lines
8.0 KiB
Nix
217 lines
8.0 KiB
Nix
{
|
|
description = "Config for triple-dezert server";
|
|
|
|
inputs = {
|
|
nixpkgs.url = "nixpkgs/nixos-24.05-small";
|
|
nixpkgs-unstable.url = "nixpkgs/nixos-unstable";
|
|
nix-inspect = {
|
|
url = "github:bluskript/nix-inspect";
|
|
inputs.nixpkgs.follows = "nixpkgs";
|
|
};
|
|
nix-inspect-unstable = {
|
|
url = "github:bluskript/nix-inspect";
|
|
inputs.nixpkgs.follows = "nixpkgs-unstable";
|
|
};
|
|
vscode-server-unstable = {
|
|
url = "github:nix-community/nixos-vscode-server";
|
|
inputs.nixpkgs.follows = "nixpkgs-unstable";
|
|
};
|
|
vscode-server = {
|
|
url = "github:nix-community/nixos-vscode-server";
|
|
inputs.nixpkgs.follows = "nixpkgs";
|
|
};
|
|
nix-on-droid = {
|
|
url = "github:nix-community/nix-on-droid";
|
|
inputs.nixpkgs.follows = "nixpkgs";
|
|
};
|
|
jovian-unstable = { # there is no stable jovian :cry:
|
|
url = "github:Jovian-Experiments/Jovian-NixOS";
|
|
inputs.nixpkgs.follows = "nixpkgs-unstable";
|
|
};
|
|
disko-unstable = {
|
|
url = "github:nix-community/disko";
|
|
inputs.nixpkgs.follows = "nixpkgs-unstable";
|
|
};
|
|
home-manager = {
|
|
url = "github:nix-community/home-manager/release-24.05";
|
|
inputs.nixpkgs.follows = "nixpkgs";
|
|
};
|
|
home-manager-unstable = {
|
|
url = "github:nix-community/home-manager";
|
|
inputs.nixpkgs.follows = "nixpkgs-unstable";
|
|
};
|
|
nix-search-cli-unstable = {
|
|
url = "github:peterldowns/nix-search-cli";
|
|
inputs.nixpkgs.follows = "nixpkgs-unstable";
|
|
};
|
|
nix-search-cli = {
|
|
url = "github:peterldowns/nix-search-cli";
|
|
inputs.nixpkgs.follows = "nixpkgs";
|
|
};
|
|
padtype-unstable = {
|
|
url = "gitlab:shelvacu/padtype";
|
|
inputs.nixpkgs.follows = "nixpkgs-unstable";
|
|
};
|
|
sops-nix = {
|
|
url = "github:Mic92/sops-nix";
|
|
inputs.nixpkgs.follows = "nixpkgs";
|
|
};
|
|
microvm = {
|
|
url = "github:astro/microvm.nix";
|
|
inputs.nixpkgs.follows = "nixpkgs";
|
|
};
|
|
nixos-hardware.url = "github:nixos/nixos-hardware";
|
|
most-winningest = {
|
|
url = "github:captain-jean-luc/most-winningest";
|
|
inputs.nixpkgs.follows = "nixpkgs";
|
|
};
|
|
};
|
|
|
|
outputs = { self, nixpkgs, nix-on-droid, home-manager, ... }@inputs: let
|
|
defaultInputs = { inherit (inputs) self nix-search-cli nix-inspect; };
|
|
defaultArgs = { inputs = defaultInputs; };
|
|
in {
|
|
debug.isoDeriv = (import "${inputs.nixpkgs}/nixos/release-small.nix" { nixpkgs = ({ revCount = 0; } // inputs.nixpkgs); });
|
|
nixosConfigurations.triple-dezert = nixpkgs.lib.nixosSystem {
|
|
system = "x86_64-linux";
|
|
modules = [ ./triple-dezert ];
|
|
specialArgs = { inputs = defaultInputs // { inherit (inputs) most-winningest; }; };
|
|
};
|
|
|
|
nixosConfigurations.compute-deck = inputs.nixpkgs-unstable.lib.nixosSystem {
|
|
system = "x86_64-linux";
|
|
modules = [ ./compute-deck ];
|
|
specialArgs = { inputs = {
|
|
jovian = inputs.jovian-unstable;
|
|
home-manager = inputs.home-manager-unstable;
|
|
vscode-server = inputs.vscode-server-unstable;
|
|
disko = inputs.disko-unstable;
|
|
padtype = inputs.padtype-unstable;
|
|
nix-search-cli = inputs.nix-search-cli-unstable;
|
|
nix-inspect = inputs.nix-inspect-unstable;
|
|
self = inputs.self;
|
|
}; };
|
|
};
|
|
|
|
nixosConfigurations.liam = nixpkgs.lib.nixosSystem {
|
|
system = "x86_64-linux";
|
|
modules = [ ./liam ];
|
|
specialArgs = { inputs = defaultInputs // { inherit (inputs) sops-nix; }; };
|
|
};
|
|
|
|
nixosConfigurations.lp0 = nixpkgs.lib.nixosSystem {
|
|
system = "x86_64-linux";
|
|
modules = [ ./lp0 ];
|
|
specialArgs = defaultArgs;
|
|
};
|
|
|
|
nixosConfigurations.shel-installer = nixpkgs.lib.nixosSystem {
|
|
system = "x86_64-linux";
|
|
modules = [ ./installer.nix ];
|
|
specialArgs = defaultArgs;
|
|
};
|
|
|
|
nixosConfigurations.devver = nixpkgs.lib.nixosSystem {
|
|
system = "x86_64-linux";
|
|
modules = [ ./devver ];
|
|
specialArgs = { inputs = defaultInputs // { inherit (inputs) home-manager; }; };
|
|
};
|
|
|
|
nixosConfigurations.fw = nixpkgs.lib.nixosSystem {
|
|
system = "x86_64-linux";
|
|
modules = [ ./fw ];
|
|
specialArgs = { inputs = defaultInputs // { inherit (inputs) nixos-hardware; }; };
|
|
};
|
|
|
|
nixOnDroidConfigurations.default = nix-on-droid.lib.nixOnDroidConfiguration {
|
|
modules = [ ./nix-on-droid ];
|
|
extraSpecialArgs = defaultArgs;
|
|
pkgs = import nixpkgs { system = "aarch64-linux"; };
|
|
};
|
|
|
|
homeConfigurations."nix-on-droid" = home-manager.lib.homeManagerConfiguration {
|
|
modules = [
|
|
./home/nix-on-droid.nix
|
|
{ _module.args.inputs = defaultInputs; }
|
|
];
|
|
pkgs = import nixpkgs { system = "aarch64-linux"; };
|
|
};
|
|
|
|
checks = nixpkgs.lib.genAttrs [ "x86_64-linux" ] (system:
|
|
let
|
|
pkgs = nixpkgs.legacyPackages.${system};
|
|
config = {
|
|
node.pkgs = pkgs;
|
|
node.pkgsReadOnly = false;
|
|
node.specialArgs.selfPackages = self.packages.${system};
|
|
#node.specialArgs.inputs = defaultInputs;
|
|
};
|
|
in
|
|
{
|
|
liam = nixpkgs.lib.nixos.runTest {
|
|
hostPkgs = pkgs;
|
|
imports = [ config ./tests/liam.nix { node.specialArgs.inputs = self.nixosConfigurations.liam._module.specialArgs.inputs; } ];
|
|
};
|
|
trip = nixpkgs.lib.nixos.runTest {
|
|
hostPkgs = pkgs;
|
|
imports = [ config ./tests/triple-dezert.nix { node.specialArgs.inputs = self.nixosConfigurations.triple-dezert._module.specialArgs.inputs; } ];
|
|
};
|
|
}
|
|
);
|
|
|
|
|
|
nixosModules.common = import ./common/module.nix;
|
|
packages.x86_64-linux.snmpb = nixpkgs.legacyPackages.x86_64-linux.libsForQt5.callPackage ./packages/snmpb/package.nix {};
|
|
packages.x86_64-linux.snmp-mibs-downloader = nixpkgs.legacyPackages.x86_64-linux.callPackage ./packages/snmp-mibs-downloader.nix {};
|
|
packages.x86_64-linux.digitalOceanImage = import ./generic-digitalocean-nixos.nix { inherit inputs; };
|
|
packages.x86_64-linux.authorizedKeys = let
|
|
pkgs = nixpkgs.legacyPackages.x86_64-linux;
|
|
in pkgs.writeText "authorizedKeys" (pkgs.lib.concatStringsSep "\n" self.nixosConfigurations.fw.config.vacu.ssh.authorizedKeys);
|
|
packages.aarch64-linux.authorizedKeys = let
|
|
pkgs = nixpkgs.legacyPackages.aarch64-linux;
|
|
in pkgs.writeText "authorizedKeys" (pkgs.lib.concatStringsSep "\n" self.nixOnDroidConfigurations.default.config.vacu.ssh.authorizedKeys);
|
|
|
|
qb = /* qb is "quick build" */ let
|
|
toplevelOf = name: self.nixosConfigurations.${name}.config.system.build.toplevel;
|
|
deterministicCerts = import ./deterministic-certs.nix { nixpkgs = inputs.nixpkgs.legacyPackages.x86_64-linux; };
|
|
pkgs = nixpkgs.legacyPackages.x86_64-linux;
|
|
in rec {
|
|
# nix-on-droid is impure >:(
|
|
# nod = self.nixOnDroidConfigurations.default.activationPackage;
|
|
fw = toplevelOf "fw";
|
|
triple-dezert = toplevelOf "triple-dezert";
|
|
trip = triple-dezert;
|
|
compute-deck = toplevelOf "compute-deck";
|
|
cd = compute-deck;
|
|
liam = toplevelOf "liam";
|
|
lp0 = toplevelOf "lp0";
|
|
devver = toplevelOf "devver";
|
|
shel-installer = toplevelOf "shel-installer";
|
|
iso = self.nixosConfigurations.shel-installer.config.system.build.isoImage;
|
|
do = self.packages.x86_64-linux.digitalOceanImage;
|
|
snmpb = self.packages.x86_64-linux.snmpb;
|
|
check-triple-dezert = self.checks.x86_64-linux.trip.driver;
|
|
check-trip = check-triple-dezert;
|
|
check-liam = self.checks.x86_64-linux.liam.driver;
|
|
|
|
authorizedKeys = self.packages.x86_64-linux.authorizedKeys;
|
|
authorizedKeysAarch = self.packages.aarch64-linux.authorizedKeys;
|
|
ak = authorizedKeys;
|
|
|
|
dc-priv = deterministicCerts.privKeyFile "test";
|
|
dc-cert = deterministicCerts.selfSigned "test" {};
|
|
};
|
|
|
|
all = let
|
|
pkgs = nixpkgs.legacyPackages.x86_64-linux;
|
|
symlinkCommands = pkgs.lib.mapAttrsToList (name: pkg: "ln -s ${pkg} ${name}") self.qb;
|
|
in pkgs.runCommand "nix-stuff-all" {} ''
|
|
mkdir $out
|
|
cd $out
|
|
${pkgs.lib.concatStringsSep "\n" symlinkCommands}
|
|
'';
|
|
|
|
allWithBuildDeps = nixpkgs.legacyPackages.x86_64-linux.closureInfo { rootPaths = [ self.all.drvPath ]; };
|
|
};
|
|
}
|